调用表单方法时访问冲突

Question

我有一个表单 TForm1，我在其中保存了 cxSpreadsheet 组件。我还创建了一个名为 TTest 的类。 TTest 类包含两种方法，一种用于加载数据，另一种用于保存数据。

当我在 TTest 类方法中调用 TForm1 类的方法时，即使创建了组件，当我调用 Test.LoadMyData 方法时也会出现访问冲突，它会导致对 ATableView1 变量的访问冲突。

我做错了什么？

type
  TForm1 = class(TForm)
    dxSpreadSheet1: TdxSpreadSheet;
    procedure FormShow(Sender: TObject);
  public
    ATableView1 : TdxSpreadSheetTableView;
    procedure Initilize;
    procedure LoadData;
  end;

  TTest = class
  public
    procedure SaveMyData(MyValue : String);
    procedure LoadMyData;
  end;

var
  Form1: TForm1;
  Test: TTest;

implementation

{$R *.dfm}

procedure TForm1.FormShow(Sender: TObject);
begin
  Form1 := TForm1.Create(Self);
  Initilize;
  Test := TTest.Create;
  Test.LoadMyData;
end;

procedure TForm1.Initilize;
begin
  ATableView1 := dxSpreadSheet1.Sheets[0] as TdxSpreadSheetTableView;
end;

procedure TForm1.LoadData;
begin
  ATableView1.Cells[10,1].SetText('Test Application');
end;

procedure TTest.LoadMyData;
begin
  Form1.LoadData;
end;

Answer 1

在您的问题中，您遗漏了一个非常重要的难题。您在 cmets 中提到过，但我在这里重复一遍，因为它是您问题的直接触发因素。在 cmets 中，您说表单的创建方式如下：

with TForm1.Create(Self) do
begin
  try
    ShowModal;
  finally
    Free;
  end;
end;

您的问题是，在ShowModal 的调用链中，您希望Form1 被分配专门分配给您刚刚创建的实例。但显然你还没有做任何设置Form1。

您的“解决方案”是在 ShowModal 调用链中分配 Form1。虽然这解决了您当前的问题，但它远非正确，我稍后会解释原因。首先，我将展示一个可以完全避免该问题的简单解决方案（请注意，它不是一个完整的解决方案，因为您的代码存在的问题比您意识到的要多得多）。

解决办法，去掉with：

//This first line is the most important.
//It explicitly sets which variable must be assigned to the new form.
Form1 := TForm1.Create(Self);
try
  Form1.ShowModal;
finally
  Form1.Free;
end;

维沙尔，试试看。如果你这样做，你会看到它有效。希望我现在得到你的全部关注。一开始你不相信，但也许你现在意识到我真的确实理解正确。

---

那么为什么我说你的“解决方案”是错误的呢？毕竟它似乎解决了问题....

好吧，您自己说过：您希望在FormShow 的开头分配Form1。你是对的，应该是。通过在FormShow 中分配Form1 := Self;，您只是在修补之前的错误。您肯定同意修复最初的错误比稍后修补它更好吗？

但是这里有一个更深层次的问题……我不确定你是否理解“对象实例”和“类”之间的区别。 （如果你这样做了，那么请继续阅读接下来的几段以进行修改。）

您似乎希望在创建TForm1 时自动将其分配给Form1 变量。就好像您预计在任何时间点内存中都只会有一个TForm1。但是TForm1是类类型；这意味着它通常定义了任意数量的相同类型的对象实例的行为。每次创建TForm1 时，它都是表单的一个新的单独实例。每个实例都可以有自己的变量分配给它。例如

JohnsForm1 := TForm1.Create(Self);
PaulsForm1 := TForm1.Create(Self);

如果您需要 2 个表单变量，请考虑一下您不正确的“解决方案”会发生什么？你会在FormShow 方法中写什么？ JohnsForm1 := Self; 或 PaulsForm1 := Self;?

当然，您仍然可以选择在内存中一次只保留一个TForm1 实例。但是 Delphi 无法自动知道这是您的意图。所以你仍然应该像上面那样明确地做任何想要的任务。

---

我提到您的代码还有更严重的问题。和上面关于对象实例和类类型的讨论有关。

你的TTest 类做了一堆不必要的假设：

• 假设永远只有 1 个 TForm1 实例。
• 它假定表单在需要时始终可用。
• 它假定表单将分配给Form1 变量。

同样，如果您需要 JohnsForm1 和 PaulsForm1，您的代码将无法正常工作。

对TTest.LoadMyData 和TForm1.FormShow 的微小改动可以解决这些问题。

//Write LoadMyData so it can be told which form instance to load the data into
procedure TTest.LoadMyData(ALoadForm: TForm1);
begin
  ALoadForm.LoadData;
end;

//Change FormShow to tell Test which form to use in LoadMyData
procedure TForm1.FormShow(Sender: TObject);
begin
  Initilize;
  Test := TTest.Create;
  Test.LoadMyData(Self);
end;

作为记录，大卫已经在his answer 中向您提供了此信息。他的回答还展示了对新 TTest 实例的适当资源保护，而为了简单起见，我将其省略了。

顺便说一句，这 2 个小改动也可以解决您的问题。
基本上，您的代码中有 2 个错误。这两个错误的结合导致了您的问题。
您可以修复其中任何一个以使问题消失。但是您应该同时修复这两个问题以使您的代码更好。

Answer 2

你陷入了困境。 Delphi 方法对隐式Self 对象（即实例）进行操作。也称为方法调用的目标。如果我们用明确的Self 编写您的代码，那么它看起来像这样：

procedure TForm1.FormShow(Sender: TObject);
begin
  Form1 := TForm1.Create(Self);
  Self.Initilize;
  Test := TTest.Create;
  Test.LoadMyData;
end;

procedure TForm1.Initilize;
begin
  Self.ATableView1 := Self.dxSpreadSheet1.Sheets[0] as TdxSpreadSheetTableView;
end;

procedure TForm1.LoadData;
begin
  Self.ATableView1.Cells[10,1].SetText('Test Application');
end;

procedure TTest.LoadMyData;
begin
  Form1.LoadData;
end;

正如您所看到的，您对Self 和Form1 的引用非常糟糕。请注意，Form1 全局变量是在 .dpr 文件中使用以下代码行实例化的：

Application.CreateForm(TForm1, Form1);

这最终导致FormShow 被Form1 调用。然后覆盖Form1，现在有两个TForm1 实例。你在Self 上调用Initilize，然后在Form1 上调用LoadData。

整个事情都是一团糟。代码可能如下所示：

// remove global variable Test

procedure TForm1.FormShow(Sender: TObject);
var
  Test: TTest;
begin
  Initilize;
  Test := TTest.Create;
  try 
    Test.LoadMyData(Self);
  finally
    Test.Free;
  end;
end;

procedure TForm1.Initilize;
begin
  ATableView1 := dxSpreadSheet1.Sheets[0] as TdxSpreadSheetTableView;
end;

procedure TForm1.LoadData;
begin
  ATableView1.Cells[10,1].SetText('Test Application');
end;

procedure TTest.LoadMyData(Form: TForm1);
begin
  Form.LoadData;
end;

我们不使用全局变量，而是将表单引用作为参数传递。

一旦您掌握了这一点，您可能会考虑完全删除全局变量 Form1。 IDE 在假设每个表单都只有一个实例的情况下创建此变量。但没有理由必须如此。就个人而言，我认为从长远来看，删除这些全局变量会让您受益。

Answer 3

正如大卫如此雄辩地指出的那样，这是你制造的一个相当混乱的局面。他说 IDE 在项目文件中插入一行，自动为您创建表单是正确的。因此，自己创建它是多余的。

在这种情况下，OnShow 处理程序可能是将一些测试数据添加到网格的正确位置，但我不会打扰 TTest 类来执行此操作。也就是说，首先让逻辑工作，然后如果需要，将这些东西移到另一个类中。我建议这样做是因为您似乎没有很好地掌握如何进行 OOD。我们都在同一时间！先把事情简单化。

我为 CodeRage 9 制作了一个您可能会觉得有趣的视频。它被称为“你最近接受了你的内部软件管道工吗？”在 YouTube 上搜索它。它会让你对这个一般性主题有一些了解（可能太多了）。

Answer 4

type
  TForm1 = class(TForm)
    dxSpreadSheet1: TdxSpreadSheet;
    procedure FormShow(Sender: TObject);
  public
    ATableView1 : TdxSpreadSheetTableView;
    procedure Initilize;
    procedure LoadData;
  end;

  TTest = class
  public
    procedure SaveMyData(MyValue : String);
    procedure LoadMyData;
  end;

var
  Form1: TForm1;
  Test: TTest;

implementation

{$R *.dfm}

procedure TForm1.FormShow(Sender: TObject);
begin
  //Form1 is nil, if I check before executing below statement.
  Form1 := Self; //This statement make my code work. mmmhhhhhaaaa Love This Statement.

  Initilize;
  Test := TTest.Create;
  Test.LoadMyData;
end;