Delphi - 分割线（程序没有响应），不分割文件大小（TTHREAD）

Question

希望每个人都做得很好。 我只有一个问题，在 Delphi 编程中...... 我有一个备忘录，它为我加载了一个文件 .txt ，它包含大行，比如 50,000Lines....

所以我想将这些行拆分为 5000 行，然后将它们加载到新的备忘录中。 例如第一次拆分，它将在新文件文本上拆分 5000 行，然后将其加载到新备忘录上，加载后（删除 5000 的文件），当然对于大 LINES 将是 45000。

第二次拆分它将从 45,000 拆分 5000 ，大行将是 40,000，新行将是 5000（文件文本）。

我为什么要拆分文件文本上的行然后加载它的原因，因为当我将文件拆分为备忘录时程序没有响应（没有响应）。

procedure TForm1.Button1Click(Sender: TObject);
var count,i ,X,m:integer;
begin
Memo2.Clear;
Label1.Caption:=IntToStr(Memo1.Lines.Count) ;
if Memo1.Lines.Count > 5000 then
X:=5000
else X:= Memo1.Lines.Count ;
for  count:=0 to x do
  begin

  Memo2.lines.add(Memo1.lines.Strings[0]);
  Memo1.Lines.Delete(0);

             Memo2.Text:=Trim(Memo2.text);

end;
end;

这是我用来将小行拆分为其他小行的代码...

在备忘录中，但当你有 100 万行时，程序将停止回答。

我添加了 trim(memo2.text) ；删除末尾的空行。

那么我如何分割行，而不是文件大小（因为它会破坏行）......我如何像我对文件文本所说的那样分割大行，然后加载并删除它，然后当我重新单击一个按钮时，它将对其他行执行相同的操作....

我知道我们必须使用 TThread 类，但我不知道如何用我的代码实现它...谢谢！

谢谢。

Answer 1

线程不是问题的答案。您不应该需要线程来执行此任务。问题出在这里：

Memo1.Lines.Delete(0);

循环执行此操作对于备忘录而言非常昂贵。文本的第一部分被删除，其余部分向上移动。

最好的办法是：

1. 将整个源移动到TStringList。
2. 将该字符串列表的前 5000 行处理为单个字符串。
3. 使用SelText := ... 将整个字符串一次性添加到备忘录中。

完成后，一键清除原始备忘录。

Answer 2

如前所述

使用 TStringList 加载和处理您的数据，使用 TMemo 显示它。

请记住：如果你做不到，那就假装它！

而且您无法在合理的时间内将 50000 行加载到标准 VCL 控件中。

所以我为您制作了一个小型示例应用程序，向您展示如何伪造它：

你需要在演示中添加错误处理，我只是采取了最短和最乐观的路径。

首先我需要一些数据，所以我生成了一个包含随机数据的文件：

procedure TForm25.GenereateTextFile(const aLines: Integer);
var
  Buffer: TStringlist;
  Line: string;
  i, j: Integer;
begin
  Buffer := TStringlist.Create;
  try
    for i := 1 to aLines do
    begin
      SetLength(Line, Random(200));
      for j := 1 to Length(Line) do
        Line[j] := Chr(ord('a') + Random(26));
      Buffer.Add(Line);
    end;

    Buffer.SaveToFile('dummy.txt');
  finally
    Buffer.Free;
  end;
end;

我称之为 FormCreate：

procedure TForm25.FormCreate(Sender: TObject);
begin
  GenereateTextFile(50000);
end;

然后我们需要生成一些GUI来显示文件：

在表单上放置一个 TTimer 并将它的 Interval 设置为 50，并为其分配一个 OnTimer 事件

过程 TForm25.Timer1Timer(Sender: TObject); 开始 Timer1.Enabled := 假； GenerateGUI(Self, 'dummy.txt'); 结束；

剩下的就是生成实际的 GUI：

procedure TForm25.GenerateGUI(const aForm: TForm; const aFileName: TFilename; aLinesPerPage: Integer = 5000);
var
  Buffer: TStringlist;
  Tmp: TStringlist;
  i, j: Integer;
  PageControl: TPageControl;
  TabSheet: TTabSheet;
  Memo: TMemo;
begin
  Buffer := TStringlist.Create;
  Buffer.LoadFromFile(aFileName);
  Buffer.BeginUpdate;

  PageControl := TPageControl.Create(aForm);
  PageControl.Parent := aForm;
  PageControl.Align := alClient;
  i := 0;

  for i := 0 to (Buffer.Count div aLinesPerPage) - 1 do
  begin
    TabSheet := TTabSheet.Create(PageControl);
    TabSheet.PageControl := PageControl;
    TabSheet.Caption := Format('Lines %d to %d', [i * aLinesPerPage, (i + 1) * aLinesPerPage - 1]);

    Memo := TMemo.Create(TabSheet);
    Memo.Parent := TabSheet;
    Memo.Align := alClient;

    j := 0;

    Tmp := TStringlist.Create;
    Tmp.BeginUpdate;
    Application.ProcessMessages;

    while j < aLinesPerPage do
    begin
      Tmp.Add(Buffer[0]);
      Buffer.Delete(0);
      inc(j);
    end;

    Memo.Lines.Assign(Tmp);
    Tmp.Free;
    Application.ProcessMessages;
  end;
  FreeAndNil(Buffer);
end;

您会看到页面一一显示并显示数据。

它一个一个出现的原因是因为我打电话给Application.ProcessMessages;，它让一点点机器人的速度变慢了很多，你告诉你的用户程序是活着的。

Answer 3

我不确定使用 TMemo 对您的应用程序有多重要，但如果您只想将一个文本文件拆分为多个文件，其中的行数相同（可能除了最后一个一个，当然），您根本不需要 TMemo，也不需要任何 Delphi 容器类，如 TStringList 或 TStream。关键是，你已经有了一个完美的容器，即文件系统。

以下是一个 Delphi 控制台应用程序，它使用自 Delphi 之前在 Object Pascal 中的文件访问方法（我可以听到一些 Delphi 粉丝对我以这种方式向您展示的啧啧啧啧，但 imo 找到其他方法并没有什么坏处，完全有效的做事方式，尤其是避免进入 Delphi 容器类的语义和用法）。

希望它的工作原理是不言而喻的。创建测试文件后，它会逐行读取它并将其输出到按顺序编号的输出文件，直到其中包含您想要的行数，或者没有更多行可读取。在我的便携式设备上，从开始到结束需要 0.078 秒。

代码：

program FileSplit;

{$APPTYPE CONSOLE}

uses
  SysUtils;

const
  MaxLines = 100000;
  LinesPerFile = 5000;
  BufferSize = 32768;

var
  MainFileName : String;

procedure CreateFile(AFileName : String);
var
  AFile : Text;
  Line : Integer;
  Buffer : Array[1..BufferSize] of Char;
  S : String;
begin
  AssignFile(AFile, AFileName);
  SetTextBuf(AFile, Buffer, SizeOf(Buffer));
  Rewrite(AFile);

  Line := 1;
  while Line <= MaxLines do begin
    S := Format('This is line: %d', [Line]);
    writeln(AFile, S);
    Inc(Line);
  end;
  Close(AFile);
end;

procedure SplitFile(AFileName : String);
var
  AFile : Text;
  SubFileNumber : Integer;
  Buffer : Array[1..BufferSize] of Char;

  procedure CreateSubFile(SubFileNumber : Integer);
  var
    OutFile : Text;
    OutBuffer : Array[1..BufferSize] of Char;
    SubFileName : String;
    S : String;
    Line : Integer;
  begin
    SubFileName := ExtractFilePath(AFileName) + IntToStr(SubFileNumber) + '.Txt';
    writeln(SubFileName);

    Assign(OutFile, SubFileName);
    SetTextBuf(OutFile, OutBuffer, SizeOf(OutBuffer));
    Rewrite(OutFile);

    Line := 1;

    // the following reads the input file a line at a time
    // and outputs it to the current output file
    // until there's nothing left to read or the lines
    // per output file is reached

    while (Line <= LinesPerFile) and not Eof(AFile) do begin
      readln(AFile, S);
      writeln(OutFile, S);
      Inc(Line);
    end;

    Close(OutFile);
  end;

begin
  Assign(AFile, AFileName);
  SetTextBuf(AFile, Buffer, SizeOf(Buffer));
  Reset(AFile);

  SubFileNumber := 1;
  while not Eof(AFile) do begin
    CreateSubFile(SubFileNumber);
    Inc(SubFileNumber);
  end;
  Close(AFile);
end;

begin
  MainFileName:= GetEnvironmentVariable('Temp');
  MainFileName := IncludeTrailingPathDelimiter(MainFileName);
  MainFileName := MainFileName + 'Main.Txt';

  CreateFile(MainFileName);
  writeln(Format('File %s created', [MainFileName]));

  SplitFile(MainFileName);
  readln;

end.

Answer 4

您可能会达到 tmemo 的限制（取决于您使用的 Delphi 版本）。当然，删除 tmemo 中的第一行需要时间，尤其是 5000 次。

您是否考虑在前 5000 行的备忘录 2 中使用 readln 和 writeln 并在其余部分使用备忘录 2（如果存在）？