使用 COL name 根据指定 Name 的 Column 中是否存在值来获取 ROW 名称答案

【问题标题】：Use COL name to Get ROW names based on whether a value exists in a Column with the specified Name使用 COL name 根据指定 Name 的 Column 中是否存在值来获取 ROW 名称
【发布时间】：2021-10-22 21:42:49
【问题描述】：

如果有人能帮我解决这个问题，我将不胜感激。

概述

在谷歌表格中，我有以下网格：

	School A	School B	School C
Tim	x		x
John
Martin	x	x
Jack			x

行是迎合某些学校的人的名字。单元格中的值“x”仅表示关系。因此，Tim 迎合 School A 和 School C，同样，Jack 只迎合 School C。

注意：单元格要么是空的，要么包含那个“x”。认为这可能会有所帮助。我们真的不需要寻找 'x' 只是一个非空单元格。

问题

我有另一个如下表，其中有一个 School 列，其中按行列出了所有学校。
我想创建一个公式来使用上面的表格并返回一个串联的字符串，列出所有为该学校提供服务的人。

School	People
School A	Tim, Martin
School B	Martin
School C	Tim, Jack

【问题讨论】：

标签： google-sheets excel-formula google-sheets-formula

【解决方案1】：

使用：

=INDEX(REGEXREPLACE(TRIM(SPLIT(FLATTEN(QUERY(TRANSPOSE(QUERY(QUERY(SPLIT(FLATTEN(
 IF(B2:D="",,B1:D1&"♠♦"&A2:A&",♦"&A2:A)), "♦"), 
 "select Col1,max(Col2) where Col2 is not nUll group by Col1 pivot Col3"), 
 "offset 1", 0)),,9^9)), "♠")), ",$", ))

【讨论】：

非常感谢！这看起来太棒了！（现在就尝试）远远超出了我的工作表技能。不过我确实有一个问题，我没有看到您引用 F 列。这会创建一个新表吗？我有一个现有的表，其中包含学校行（以及它前面的其他列）。在上面的示例中，我想使用 F2、F3、F4 中的值在 G2、G3、G4 中添加公式
顺便说一句，你太棒了！！！
这很好用，我绝对可以使用它并从此表中查找。但是我在 ", Craig, Crowder, Hann, Maciel" 这样的字符串中得到领先的 ','
@Tahir 如果您想进行查找，请使用：=INDEX(IFNA(VLOOKUP(F2:F, REGEXREPLACE(TRIM(SPLIT(FLATTEN(QUERY( {B1:D1&"♦"; IF(B2:D="",,A2:A&",")},,9^9)), "♦")), ",$", ), 2, 0)))

【解决方案2】：

或：

=INDEX(REGEXREPLACE(TRIM(SPLIT(FLATTEN(QUERY(
 {B1:D1&"♦"; IF(B2:D="",,A2:A&",")},,9^9)), "♦")), ",$", ))

【讨论】：

这个工作完美！非常感谢！我很感激！