Google 电子表格中的数组公式总和

Question

你怎么arrayformula()一个sum()比如：

=sum(A1:H1)

我需要往下走 1000 行。

Answer 1

另一种选择：

=ArrayFormula(SUMIF(IF(COLUMN(A1:H1),ROW(A1:A1000)),ROW(A1:A1000),A1:H1000))

Answer 2

在 Jacob Jan Tuinstra 和 AdamL 这两个有效答案中，Jacob 给出了更好的答案。 Jacob's 跑得更快，更容易记住。

但是，既然充分利用 Google 表格要容易得多，为什么还要使用疯狂的公式呢？

=ARRAYFORMULA(A2:A+B2:B+C2:C+D2:D+E2:E+F2:F+G2:G+H2:H) 

在上述公式中，您可以使用命名范围而不是引用范围。

=ARRAYFORMULA(range1+range2+range3+range4+range5+range6+range7+range8) 

此外，您可以对跨工作表的行求和，而不是被困在同一个工作表中的列上。

要修复公式以阻止为空白行返回零，请使用：

=arrayFormula(if(isNumber(A2:A),A2:A+B2:B+C2:C+D2:D+E2:E+F2:F,G2:G,H2:H))

见：See Ahab's answer on Google Forums

一个很酷的累加公式，见Otávio Alves Ribeiro's answer on Google Forums

Answer 3

这就是你要找的：

=MMULT(A1:H1000,TRANSPOSE(ARRAYFORMULA(COLUMN(A1:H1000)^0)))

在我给出的 Web 应用程序上查看此答案：https://webapps.stackexchange.com/a/53419/29140

注意：在新的 Google 电子表格上尝试过，但没有成功。

Answer 4

将 A-H 水平求和并向下运行 523 行：

=ARRAYFORMULA(iferror(mmult(A1:H523;TRANSPOSE(column(A1:H1))^0)))

Answer 5

如果我看一下这个公式，我真的认为以下可能更简单。将此添加到工具 > 脚本编辑器：

function row_sum(range_to_sum_per_row) {
  var result_column = [];
  for (var r = 0; r < range_to_sum_per_row.length; r++) {
    var row_sum = parseFloat(0);
    for (var c = 0; c < range_to_sum_per_row[r].length; c++) {
        row_sum += range_to_sum_per_row[r][c] || 0;
    }
    result_column.push([row_sum]);
  }
  return result_column;
}

出于性能原因，这样使用，其中 C:H 是您要总结的范围，A:A 是不包含空字符串的列：

=row_sum(filter(C2:H, len(A2:A)>0))

Answer 6

如果您希望能够为 A1:H 中的所有值添加行并对最后一行求和，您可以使用：

 =ArrayFormula(SUMIF(IF(COLUMN(A1:H1),ROW(A1:A)),ROW(A1:A),A1:H))

或者，如果您希望能够在电子表格中添加行和列并将两者的最后一个相加，也可以这样做。将以下代码粘贴到任何单元格中，它将为粘贴单元格下方和右侧每行中的所有单元格创建一列总和值：

=arrayformula(SUMIF(IF(COLUMN(indirect(concatenate(REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", ""),VALUE(REGEXREPLACE(address(row(),column()),"[^[:digit:]]", "")),":",VALUE(REGEXREPLACE(address(row(),column()),"[^[:digit:]]", ""))))),ROW(indirect(concatenate(REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", ""),VALUE(REGEXREPLACE(address(row(),column()),"[^[:digit:]]", "")),":",REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", ""))))),ROW(indirect(concatenate(REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", ""),VALUE(REGEXREPLACE(address(row(),column()),"[^[:digit:]]", "")),":",REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", "")))),indirect(concatenate(concatenate(REGEXREPLACE(address(row(),column()+1),"[^[:alpha:]]", ""),VALUE(REGEXREPLACE(address(row(),column()),"[^[:digit:]]", "")),":"),address(rows($A:$A),columns($1:$1))))))

Answer 7

使用查询

=INDEX(TRANSPOSE(
  QUERY(TRANSPOSE(FILTER(A2:H,A2:A<>"")),
  "select sum(Col"&JOIN("), sum(Col",SEQUENCE(COUNTA(A2:A)))&")",0)
),,2)

注释：

• 动态生成查询字符串

Answer 8

使用DSUM：

=ARRAYFORMULA(DSUM(
  TRANSPOSE(FILTER({A2:A,A2:H},A2:A<>"")),
  SEQUENCE(COUNTA(A2:A)),{IFERROR(1/0);IFERROR(1/0)}))

注释：

• {IFERROR(1/0);IFERROR(1/0)} 是为DSUM 设置零标准。

• {A2:A,A2:H} -- 为 DSUM 添加假列以模仿标题列。

• 可以将公式转换为DMAX 或DAVERAGE

Answer 9

答案类似于@adamL 建议，但删除了内部if。

=ArrayFormula(
     sumif(ROW(A1:A10)*COLUMN(A1:H1)^0,ROW(A1:A10),A1:A10)
 )

在这种情况下，我使用ROW(A1:A10) * COLUMN(A1:H1)^0 来生成行号矩阵。要了解它的工作原理，您可以在 Google 表格中仅测试这一部分：

= ArrayFormula(ROW(A1:A10) * COLUMN(A1:H1)^0)

所以，用你的行矩阵，sumif可以对每一行进行运算，是行有匹配的行号，就会被求和。

Answer 10

我们不要让这件事复杂化。 只需将括号放在范围内的每个数组中即可。

=arrayformula( Sum( (A1:A):(H1:H) )

这不仅跨越了 1000 行，而且跨越了无穷大。

如果你真的想限制，那就去吧

=arrayformula( Sum( (A1:A1000):(H1:H1000) )