满足 IF 条件的 VLOOKUP

Question

我在使用正确的案例编号填充工作表时遇到了这个问题。

Sheet 1: (Report)
SSN         | Service Date
123456      | 10/01/2014

Sheet 2: (Data)
SSN         | Case Number  | Start Date | End Date
123456      | 0000000      | 01/01/2010 | 12/31/2012
123456      | 1111111      | 01/01/2013 | 05/31/2014
123456      | 2222222      | 06/01/2014 | 11/10/2015

如何根据服务日期在另一张工作表的开始和结束日期的“范围”内进行 VLOOKUP？

在这种情况下，我想查找 SSN 并返回案例编号 2222222，因为该案例在该服务日期有效。

我在网上查找并找到“MATCH”。我可以匹配case的第一个结果匹配SSN，但是如果不匹配怎么去下一个case呢？

=IF(E2>=INDEX('CASE NUMBERS'!A:F,MATCH(C2,'CASE NUMBERS'!A:A,0),4)&E2<=INDEX('CASE NUMBERS'!A:F,MATCH(C2,'CASE NUMBERS'!A:A,0),5),"YES","NO")

我在工作中在 Windows 7 上使用 Excel 2013。

Answer 1

您将需要 3 个条件。 a) 开始日期是否小于服务日期 b) 结束日期是否大于服务日期 c) SSN 号码是否匹配？

使用较新的AGGREGATE¹ function 强制任何不匹配项进入错误状态，同时使用忽略错误选项（例如6）丢弃错误。

=INDEX(Sheet2!$B$2:$B$9999, AGGREGATE(15, 6, ROW($1:$9998)/((Sheet2!C$2:C$9999<=B2)*(Sheet2!D$2:D$9999>=B2)*(Sheet2!A$2:A$9999=A2)), 1))

      

出于所有意图和目的，工作表公式将 FALSE 视为零（例如 0），将 TRUE 视为一（例如 1）。任何数乘以零都是零，任何数乘以一都是同一个数。 AGGREGATE 函数正在检索 Sheet2!B2"B9999 中第一个匹配项的行位置。该行位置将是 ROW(1:9998) 中某处的数字。任何不匹配所有三个条件的行将至少具有一个零乘以分母。这使分母为零。任何除以零都会导致 #DIV/0! 错误，并且 AGGREGATE 将从结果集中丢弃这些错误。AGGREGATE 的 15 选项是 SMALL 和最后一个 1 是 SMALL 的 k 序数（最小的）。因此，在匹配所有三个条件的所有行中，AGGREGATE 将最低的行返回给INDEX function从 Sheet2!B2"B9999 中检索值。

将范围缩小到最多 5 行，并使用Evaluate Formula 命令逐步执行公式并获得更好的理解。

值得注意的是，转换此公式以检索第二个、第三个等匹配项非常容易，因为它只需要对 k 序数进行排序。

---

¹ _{AGGREGATE function 是随 Excel 2010 引入的。它在早期版本中不可用。}

Answer 2

如果SSN 在两张纸的 A1 中，并且您的 Case Numbers 是数字（0000000 除外），那么您可以尝试：

=SUMIFS(Sheet2!B:B,Sheet2!A:A,A2,Sheet2!C:C,"<="&B2,Sheet2!D:D,">="&B2)  

SUMIFS 解释为here（以及其他地方！）。

Answer 3

此数组公式将始终打印最后一个匹配项：

=INDEX(Sheet2!B:B,MAX((Sheet2!A:A=A2)*(Sheet2!C:C<=B2)*(Sheet2!D:D>=B2)*ROW(A:A)))

这是一个数组公式，必须用Ctrl+Shift+Enter确认。

• 如果有多个符合条件的解决方案，它就可以工作
• 它还适用于您要显示的各种数据（值/日期/字符串）

! 但是，您应该尽可能缩短范围。 （整个工作表的计算量很大）