如果满足条件，则单击 HTML 元素

Question

我想知道如果满足另一个条件，我如何设法通过 VBA 单击 html 元素。为了清楚起见，我将向您展示一个简短的示例：

我需要分析特定季度的数据（假设我需要 Q2），并且每个季度的 html 元素都分组在同一页面中的 class=module_item (EXAMPLE) 中。

网站是https://investor.apple.com/investor-relations/default.aspx

我的代码是这样的：

Dim IE As New InternetExplorer
Dim iedoc As MSHTML.HTMLDocument
Dim element As MSHTML.IHTMLElement
Dim elements As MSHTML.IHTMLElementCollection
Dim quarter As MSHTML.IHTMLElement
Dim freport As MSHTML.IHTMLElement

With IE:
    .navigate "https://investor.apple.com/investor-relations/default.aspx"
    .Visible = True
End With

Do While IE.readyState <> READYSTATE_COMPLETE
Loop

Set iedoc = IE.document

Set elements = iedoc.getElementsByClassName("module_item")
Set quarter = iedoc.getElementsByClassName("module-financial_year-text")
Set freport = iedoc.getElementsByClassName("module_link module_link-statement")

For Each element In elements:
    If quarter.innerText = "Q2" Then
    freport.Click
    End If
    Debug.Print element.innerText
    Next element


End Sub

你能帮帮我吗？

Answer 1

您可以使用带有 * 包含运算符的 css attribute = value 选择器来测试是否存在包含季度描述的 href 属性

Dim link As Object, targetQtr As String, cssSelector As String, quarter As Object

targetQtr = "second"
cssSelector = "[href*='apple-reports-" & targetQtr & "-quarter-results/']"
Set quarter = ie.document.querySelectorAll(cssSelector)

If Not quarter.Length = 0 Then
    quarter.Item(0).Click
Else
    MsgBox "Quarter not found"
End If

---

另外，使用适当的页面加载等待：

While IE.busy Or IE.readyState <> 4: DoEvents: Wend

---

您还可以在字典中收集所有季度及其链接，以便您可以使用适当的季度键 .navigate 到任何特定季度，例如"second" 检索关联的 url。这意味着您还可以测试密钥是否存在。这样做的好处是您已经准备好所有链接，而不必来回访问着陆页。

Option Explicit

Public Sub test()
    Dim ie As Object, quarters As Object, quarterLinks As Object, targetQuarter As String
    Dim link As String, i As Long, arr() As String, key As Variant

    Set ie = CreateObject("InternetExplorer.Application")
    targetQuarter = "second"

    With ie
        .Visible = True
        .navigate2 "https://investor.apple.com/investor-relations/default.aspx"
        While .busy Or .readystate <> 4: DoEvents: Wend
        Set quarters = .document.querySelectorAll("[href*='-quarter-results/'].module_link-news")

        Set quarterLinks = CreateObject("Scripting.Dictionary")

        For i = 0 To quarters.Length - 1
            link = quarters.Item(i).href
            arr = Split(link, "-")
            quarterLinks(arr(2)) = link
        Next

        If quarterLinks.exists(targetQuarter) Then .navigate2 quarterLinks(targetQuarter)

        While .busy Or .readystate <> 4: DoEvents: Wend

        Stop                                     '<=delete me later
        .Quit
    End With
End Sub