TJSONObject 销毁方法错误

Question

尝试使用 TJSONObject (Delphi XE4) 解析 JSON 文件。

解析后我想销毁 TJSONObject 以防止内存泄漏，但是：

procedure TfmMain.ReadIngrJSON(const fName: string);
var i: integer;
    S: TStringList;
    JSONObject, innerObject: TJSONObject;
    innerArray: TJSONArray;
begin
S:=TStringList.Create;
try
  S.LoadFromFile(fName);
  JSONObject:=TJSONObject.ParseJSONValue(S.Text) as TJSONObject;
  if Assigned(JSONObject) then
    begin
      SetLength(ingrArray, JSONObject.Size);
      for i := 0 to JSONObject.Size-1 do
        begin
          ingrArray[i].id:=JSONObject.Get(i).JsonString.Value;
          innerObject:=JSONObject.Get(ingrArray[i].id).JsonValue as TJSONObject;

          innerArray:=innerObject.Get('en').JsonValue as TJSONArray;
          ingrArray[i].name[0]:=innerArray.Get(0).Value;
          ingrArray[i].units[0]:=innerArray.Get(1).Value;

          innerArray:=innerObject.Get('ru').JsonValue as TJSONArray;
          ingrArray[i].name[1]:=innerArray.Get(0).Value;
          ingrArray[i].units[1]:=innerArray.Get(1).Value;
          innerArray:=nil;
        end;
      innerObject.Destroy;

      for i := 0 to Length(ingrArray)-1 do
        listIngredients.Items.Add(ingrArray[i].name[1]);

    end
  else
    raise Exception.Create('no JSON data');
finally
  JSONObject.Destroy;  //here is an error 'invalid pointer operation'
  S.Free;
end;

end;

我的代码有什么问题？

Answer 1

正确的模式 - 甚至内置在 Delphi 代码模板中也是

Object-var := Object-Class.Create; // or any other way to create the instance
try
    // ...
finally
  Object-var.Destroy;
end;

相反，您将对象创建放在 try 和 finally 之间的代码中间，这为您提供以下保证：

• 如果在 S.LoadFromFile(fName); 中发生一些异常，这将通过垃圾指针调用 Destroy。

• 如果在 JSONObject:=TJSONObject.ParseJSONValue(S.Text) as TJSONObject; 中发生某些异常，这将通过垃圾指针调用 Destroy。

• 如果nil 是JSONObject:=TJSONObject.ParseJSONValue(S.Text) as TJSONObject; 的结果，这将在nil 指针上调用Destroy；

---

总的来说，我听说 DBX JSON 没有什么好处 - 许多人抱怨错误或工作缓慢。而且你看起来也很难理解什么是对象生命周期以及如何在 Delphi 中管理它。出于这两个原因，我认为您最好使用经过多年测试的 refcounting-bases JSON 库而不是 DBX。

http://superobject.googlecode.com/git/readme.html

Answer 2

释放对Get 的调用返回的引用不是您的责任。该责任在于您在代码JSONObject 中调用Get 的对象。您必须删除调用innerObject.Destroy 的行。

您遇到 invalid pointer operation 错误的原因是 JSONObject 正在尝试销毁您已经销毁的对象。

---

您通常不会调用Destroy，以防您调用它的引用恰好是nil。而是调用Free，它执行nil 检查并在引用为nil 时跳过对Destroy 的调用。

最后，您对 finally 的使用不正确。正确的模式是：

obj := TSomeClass.Create;
try
  // use obj
finally
  obj.Free; // obj.Destroy is also fine in this case because obj <> nil
end;

您必须在构造函数分配给引用之后立即放置try。如果你把它放在前面，那么你对Free 的调用可以作用于一个未初始化的引用。如果你不马上把它放在后面，那么你可能会泄漏。

对于您的 JSON 对象，您可以这样写：

JSONObject := TJSONObject.ParseJSONValue(S.Text) as TJSONObject;
if Assigned(JSONObject) then
  try
    ....
  finally
    JSONObject.Free;
  end;

或者你也可以这样做：

JSONObject := TJSONObject.ParseJSONValue(S.Text) as TJSONObject;
try
  if Assigned(JSONObject) then
  begin
    ....
  end;
finally
  JSONObject.Free;
end;