如何根据开始和结束时间值创建动态表？

Question

我有一个关于根据从一页传递到另一页的值创建动态表的问题。在第一页上，我定义了开始时间、结束时间和增量间隔。因此，在我选择开始时间后，让我们说上午 8:00 并选择会议长度 15 分钟，结束时间将根据开始时间以 15 分钟的间隔创建。示例结束时间：上午 8:15、上午 8:30、上午 8:45 等等，直到我最后一个不能大于晚上 9:00 的值。我可以为我的结束时间选择任何这些值。在我选择这三个值开始、结束和会议长度后，我点击提交，将我带到第二页。在此页面上，我想根据传递的值创建表。这是我到目前为止的代码：

<form name="myForm" id="myForm" method="post" action="SeconfPage.cfm">
        <fieldset>
            <table>
            <tr>
                <th>Date</th>
                <td><input type="date" id="datepicker" name="datepicker"/></td>
            </tr>
            <tr>
                <th>Start Time</th>
                <td><input type="text" id="stime" name="stime"/></td>
            </tr>
            <tr>
                <th>Length of meeting</th>
                <td>
                <select name="meeting" id="meeting">
                    <option value="">--Select length--</option>
                </select>
                </td>
            </tr>
            <tr>
                <th>End Time</th>
                <td><input type="text" id="etime" name="etime"></td>
            </tr>
            <tr>
                <td><input type="button" value="Create" onClick="getTable()"></td>
            </tr>
        </table>
    </fieldset>
</form>

$(function() {
        for (var i = 5; i <= 60; i += 5) {
            $('#meeting').append('<option value="' + i + '">' + i + '   min' + '</option>');
        }

        function setEndTime() {
            var meetingLength = parseInt($('#meeting').find('option:selected').val() || 0);
            var selectedTime = $('#stime').timepicker('getTime');
            if(selectedTime == null || selectedTime == ""){
                alert("Please select the start time");
            }else{
                selectedTime.setMinutes(selectedTime.getMinutes() + parseInt(meetingLength, 10), 0);
                $('#etime').timepicker('option', 'minTime', selectedTime);
                $('#etime').timepicker('setTime', selectedTime);
            }
        }

        $('#stime').timepicker({
            'timeFormat':'h:i a',
            'minTime': '8:00 AM',
            'maxTime': '9:00 PM',
            'step': 30
          }).on('changeTime', function () {
            setEndTime();
        });

        var count = 0;
        $('#etime').timepicker({
            'timeFormat':'h:i a' + ' (Slot '+count+')',
            'minTime': '8:00 AM',
            'maxTime': '9:00 PM',
            'step': function () {
                var val = parseInt($('#meeting').find('option:selected').val());
                count++
                return val;
            },

        });


        $('#meeting').bind('change', function () {
            setEndTime();
        });
    });

    function getTable(){
            document.myForm.submit();
    }

我试图弄清楚如何以及在第二页上创建表格的最佳方法是什么。所有值都是从我的表单传递的。例如在我的第二页：

start time: 8:00am
end time: 5:00pm
meeting length: 20min

我的想法是创建一个类似这样的 for 循环：

for(var i=stime; i<=etime; i+=meeting){
   var tbl = "<tr><td>"+stime+"-"+i+"</td></tr>"
}

这样的东西会给我开始时间和基于增量的下一个值。此外，一旦创建表，将此表存储在 MySQL 数据库中的最佳方法是什么？我仍然没有弄清楚如何让它工作。如果有人可以给我一个提示，最好的方法是什么，我是否走在正确的道路上。

提前致谢。

Answer 1

请尝试以下方法（用于在第 2 页创建表格）：

<cfscript>
  //existence and type checking
  param name="FORM.datepicker" type="date";
  param name="FORM.sTime" type="time";
  param name="FORM.eTime" type="time";
  param name="FORM.meeting" type="range" min=5 max=60;//minutes
  //create currentTimeSlotBegin and lastTimeSlotBegin for cfloop
  currentTimeSlotBegin = createDateTime(year(FORM.datepicker), month(FORM.datepicker), day(FORM.datepicker), hour(FORM.sTime), minute(FORM.sTime), 0);//this will be incremented, within cfloop, for each time slot
  lastTimeSlotEnd = createDateTime(year(FORM.datepicker), month(FORM.datepicker), day(FORM.datepicker), hour(FORM.eTime), minute(FORM.eTime), 0);//used only for creating lastTimeSlotBegin below
  lastTimeSlotBegin = dateAdd("n", FORM.meeting*-1, lastTimeSlotEnd);//subtract meeting length to get beginning of last time slot
</cfscript>
<table>
  <tr>
    <th>Time Slots for <cfoutput>#dateFormat(FORM.datepicker, "ddd, mmm dd, yyyy")#</cfoutput></th>
  </tr>
  <cfloop condition="currentTimeSlotBegin lte lastTimeSlotBegin">
    <cfset currentTimeSlotEnd = dateAdd("n", FORM.meeting, currentTimeSlotBegin)>
    <tr>
      <td><cfoutput>#timeFormat(currentTimeSlotBegin, "hh:nn tt")#-#timeFormat(currentTimeSlotEnd, "hh:nn tt")#</cfoutput></td>
    </tr>
    <cfset currentTimeSlotBegin = dateAdd("n", FORM.meeting, currentTimeSlotBegin)>
  </cfloop>
</table>

谢谢！，

-亚伦

Answer 2

这有点像您要找的吗，它是一个使用另一个表数据创建并填充的表

https://github.com/TheOriginalDeveloper/Dynamic-and-responsive-table

Answer 3

我会做一些假设...在这些会议时段会发生一些事情，并且会议通常在时间和在某个日期（因此只是一个日期时间在数据库表中）。

同意 Leigh 的观点，您想要做什么决定了数据结构，然后使用该查询来构建您的数据显示（在本例中为表格）。所以如果你最终需要存储的数据是

dateTimeStamp                 ¦ meetingID     ¦  meetingSlotData
{ts '2015-07-04 20:00:00'}    ¦ 1             ¦  Peter Pan
{ts '2015-07-04 20:15:00'}    ¦ 1             ¦  Wendy

首先使用您的日期时间选择器来填充数据表（现在只是手动完成）

 <cfset newQuery = queryNew("dateTimeStamp, meetingID, meetingSlotData","Timestamp, Integer, VarChar")>
 <cfset queryAddRow(newQuery, 2)>
 <cfset querySetCell(newQuery, "dateTimeStamp", {ts '2015-07-04 20:00:00'}, 1)>
 <cfset querySetCell(newQuery, "meetingID", 1, 1)>
 <cfset querySetCell(newQuery, "dateTimeStamp", {ts '2015-07-04 20:10:00'}, 2)>
 <cfset querySetCell(newQuery, "meetingID", 1, 2)>

 <cfdump var="#newQuery#">

然后查询数据来建表

<cfquery name="getMeeting">
    SELECT *
    FROM meetings
    WHERE id = 1
</cfquery>

<table>
<cfoutput query = "getMeeting">
    <tr><td>#dateTimeStamp#</td><td>#meetingID#</td></tr>
</cfoutput> 
</table>