Delphi 不兼容的类型

Question

我有一个非常奇怪的错误，我尝试重新启动我的 IDE，但它没有修复它。

我创建了一个如下所示的界面：

myInterface = interface
 ['{delphi guid key here}'] (CTRL+ALT+G)
 function getDataPCE : IDataPCE;
 property dataPCE : IDataPCE read getDataPCE;
 (some other properties that works)
end;

然后我创建了继承自这个接口的对象

myObject = class(TInterfacedObject, myInterface)
 private
  ... 
  function getDataPCE : IDataPCE;
  ...
 public
  ...
  property dataPCE : IDataPCE read getDataPCE;
  ...
 end;

“...”表示其他一些属性和功能，但与此无关。

我收到此错误：“不兼容的类型”

我该如何解决这个问题？

编辑

    IInfoNotisReservation = interface
      ['{AE5CEC31-B2CE-4A3D-9CFE-6393646E4A04}']

      function getNumberPCE : String;
      function getDataPCE(numRegister : String; numPCEFormated : String): IRioPiece;
      procedure setNumberPCE(NumberPCE: String);
      function getRegName : String;
      procedure setRegName(RegName: String);
      function getRegKey : String;
      procedure setRegKey(RegKey: String);

      property NumberPCE : String read getNumberPCE write setNumberPCE;
      property RegName : String read getRegName write setRegName;
      property RegKey : String read getRegKey write setRegKey;
      property DataPCE : IRioPiece read getDataPCE;
    end;

type
  TInfoNotisReservation = class(TInterfacedObject, IInfoNotisReservation)

  private
    DataBase  : IDataBase;
    SuperRio  : ISuperRio;
    RioN      : IRio;
    fPCENum    : String;

    function getDataPCE(numRegister : String; numPCEFormated : String): IRioPiece;
    function getNumberPCE: string;
    function getRegKey: string;
    function getRegName: string;
    procedure setNumberPCE(NumberPCE: string);
    procedure setRegKey(RegKey: string);
    procedure setRegName(RegName: string);
    procedure setRioN(Registre: string);
  public
    Constructor Create;
    property DataPCE : IRioPiece read getDataPCE;
    property NumberPCE : String read getNumberPCE write setNumberPCE;
    property RegName : String read getRegName write setRegName;
    property RegKey : String read getRegKey write setRegKey;

end;

function TInfoNotisReservation.getDataPCE(numRegister,
  numPCEFormated: String): IRioPiece;
begin
  setRioN(numRegister);
  Result := RioN.GetPieceByID(RioN.PieceNumberToID(NumPCEFormated).Item[0].ID, FLAG_IGNORE_SECURITY);
end;

Answer 1

为了帮助您了解如何提问，这里是您应该提交的 MCVE。

type
  IRioPiece = interface
  end;

  IInfoNotisReservation = interface
    ['{AE5CEC31-B2CE-4A3D-9CFE-6393646E4A04}']
    function getDataPCE(numRegister: String; numPCEFormated: String): IRioPiece;
    property dataPCE: IRioPiece read getDataPCE; // ERROR HERE
  end;

begin
end.

这会导致这个错误：

[dcc32 错误] E2008 类型不兼容

原因是IRioPiece 类型属性的属性getter 必须是不接受任何参数且返回类型为IRioPiece 的函数。但是您的 getter 函数需要两个参数，并且它们需要来自某个地方。如上所述，当您访问该属性时，不会提供这些参数。

因此您可以通过将getDataPCE 的声明更改为：

function getDataPCE: IRioPiece;

但这几乎肯定是错误的解决方案。大概您将这些参数声明为getDataPCE，因为您需要提供它们。在这种情况下，您无法删除它们。这意味着您不能声明由getDataPCE 支持的简单属性dataPCE。我的猜测是您只需要删除 dataPCE 属性即可。

当然，您可以像这样声明array property：

property dataPCE[numRegister: String; numPCEFormated: String]: IRioPiece 
  read getDataPCE;

这意味着您可以像这样访问该属性：

dataPCE := resvervation.dataPCE[numRegister, numPCEFormatted];

但对我来说，这太过分了。我认为最好使用函数来访问它。

结论

删除dataPCE 属性，让接口的消费者调用getDataPCE。