lex 和 yacc : 一个有语法错误的简单计算器

Question

一个简单的计算器只支持 + - * / 和整数。我使用 GNU/Linux。

hoc1.l:

%{
#include "y.tab.h"
extern int yylval;
%}

%%
[ \t] { ; }
[0-9]+ { sscanf(yytext, "%d", &yylval); printf("\nget %d\n", yylval); return NUMBER; }
\n  {return 0;}
%%

int yywrap(void) {
    return 1;
}

hoc1.y

%{
#include<stdio.h>
#define YYSTYPE int
%}
%token NUMBER
%left '+' '-'
%left '*' '/'
%%
list:   
    | list '\n'
    | list expr '\n'  {printf("\t%d\n",$2);}
    ;
expr:   NUMBER        { $$ = $1; }
    |   expr '+' expr {$$ = $1+$3;}
    |   expr '-' expr {$$ = $1-$3;}
    |   expr '*' expr {$$ = $1*$3;}
    |   expr '/' expr {$$ = $1/$3;}
    ;
%%

int main(void)
{
    yyparse();
    return 0;
}

int yyerror(char *s) {
    fprintf(stderr, "*%s*\n", s);
    return 0;
}

运行时错误：

% ./hoc
8+9

get 8
+
get 9
*syntax error*

为什么以及如何解决它，谢谢！

Answer 1

您忘记在您的 lex 文件中包含您的运算符，并且您应该在成功读取令牌时返回非零值：直观地返回 0 表示 yylex 没有匹配项。删除 lex 文件中处理换行符的行并将其替换为以下内容：

[-+*/\n] { return *yytext; }
. { yyerror("unrecognized character"); return 0; }

现在应该可以了。返回 *yytext 允许您的 yacc 语法成功解析表达式，例如如果你得到一个'+'，返回它以允许语法正确解析。