CMake target_sources 并安装

Question

我很难弄清楚如何安装target_sources() 中指定的PUBLIC 标头。

似乎target_sources() 对于除了将私有源添加到可执行文件之外的任何东西都有些神秘。 在阅读了大量材料后，尤其是 this blog entry 很有帮助，我设法理解并绕过了 target_sources() 和 PUBLIC 文件的问题。我的 C++ 库项目的许多子目录之一中的 CMakeLists.txt 如下所示：

target_sources(mylib
    PRIVATE
        foo.cpp

    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/foo.hpp>
        $<INSTALL_INTERFACE:foo.hpp>
)

这使我能够成功构建库。但是，在安装时，target_sources() 的 PUBLIC 部分中列出的头文件永远不会安装。

我的安装如下所示：

install(
    TARGETS
        mylib
    EXPORT mylib-targets
    LIBRARY
        DESTINATION ${CMAKE_INSTALL_LIBDIR}
        COMPONENT lib
    ARCHIVE
        DESTINATION ${CMAKE_INSTALL_LIBDIR}
        COMPONENT lib
    RUNTIME
        DESTINATION ${CMAKE_INSTALL_BINDIR}
        COMPONENT bin
    INCLUDES
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mylib

但是，这不会安装任何标头。 这个stackoverflow answer 提到了PUBLIC_HEADER 的使用，但阅读文档并没有让我觉得这与我的情况相关。

问题：使用install() 安装PUBLIC 或INTERFACE 标头的正确方法是什么？

背景：我的目标是在我的源代码树的每个子目录中都有一个单独的CMakeLists.txt。这些列表中的每一个都应该使用target_sources() 将PRIVATE 和PUBLIC 文件添加到构建中。所有PUBLIC（和INTERFACE）源都应该在安装过程中安装。

Answer 1

target_sources 命令的PUBLIC 部分 nothing common 与 public headers 安装了install 命令的PUBLIC_HEADER 选项。

您希望将库视为public 的标头应列在目标的PUBLIC_HEADER 属性中。

install(TARGETS) 的文档有一个很好的设置和安装私有标头的示例。在您的情况下，这将是：

# This defines `foo.hpp` located in the current source directory as a 'public header'.
set_target_properties(mylib PROPERTIES PUBLIC_HEADER foo.hpp)
# This install public headers among with the library.
install(
  TARGETS
    mylib
  PUBLIC_HEADER
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mylib
  # ... other options
)

另请参阅相关问题：How to configure CMakeLists.txt to install public headers of a shared library?。

---

另请注意，install(TARGETS) 命令的 INCLUDES 和 PUBLIC_HEADERS 子句是不同的东西：

• INCLUDES 指定已安装库的包含目录
• PUBLIC_HEADERS 指定安装时将复制所有目标公共标头的目录。

例如如果您希望通过

使用您的头文件

#include <mylib/foo.h>

那么您需要为install() 命令提供以下选项：

  PUBLIC_HEADER
    # The header will be places at ${CMAKE_INSTALL_INCLUDEDIR}/mylib/foo.h
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mylib
  INCLUDES
    # This directory will be used as include directory.
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}

所以<include-directory>（通过/）与#include<> 指令中的相对路径 相结合，将为头文件提供绝对路径。