通过生成素数使用 QuickCheck

Question

背景

为了好玩，我正在尝试编写一个用于快速检查的属性，以测试cryptography with RSA 背后的基本思想。

• 选择两个不同的素数，p 和 q。
• 让N = p*q
• e 是 relatively prime 到 (p-1)(q-1) 的某个数字（实际上，对于快速编码，e 通常为 3）
• d 是 e 模 (p-1)(q-1) 的 modular inverse

对于所有x 和1 < x < N，(x^e)^d = x modulo N 总是正确的

换句话说，x 是“消息”，将其提升到 eth 幂 mod N 是“编码”消息的行为，并将编码后的消息提升到 dth power mod N 是“解码”它的行为。

（对于x = 1，该属性也是微不足道的，这是它自己加密的情况）

代码

以下是我目前编写的方法：

import Test.QuickCheck

-- modular exponentiation
modExp :: Integral a => a -> a -> a -> a
modExp y z n = modExp' (y `mod` n) z `mod` n
    where modExp' y z | z == 0 = 1
                      | even z =  modExp (y*y) (z `div` 2) n
                      | odd z  = (modExp (y*y) (z `div` 2) n) * y

-- relatively prime
rPrime :: Integral a => a -> a -> Bool
rPrime a b = gcd a b == 1

-- multiplicative inverse (modular)
mInverse :: Integral a => a -> a -> a
mInverse 1 _ = 1
mInverse x y = (n * y + 1) `div` x
    where n = x - mInverse (y `mod` x) x

-- just a quick way to test for primality
n `divides` x = x `mod` n == 0
primes = 2:filter isPrime [3..]
isPrime x = null . filter (`divides` x) $ takeWhile (\y -> y*y <= x) primes

-- the property
prop_rsa (p,q,x) = isPrime p  &&
                   isPrime q  &&
                   p /= q     &&
                   x > 1      &&
                   x < n      &&
                   rPrime e t ==>
                   x == (x `powModN` e) `powModN` d
    where e = 3
          n = p*q
          t = (p-1)*(q-1)
          d = mInverse e t
          a `powModN` b = modExp a b n

（感谢谷歌和随机博客，implementation of modular multiplicative inverse）

问题

问题应该很明显：该属性的条件太多，无法使其完全可用。尝试在 ghci 中调用 quickCheck prop_rsa 使我的终端挂起。

所以我在QuickCheck manual 周围戳了一下，它说：

属性可以采用以下形式

forAll <generator> $ \<pattern> -> <property>

如何为素数创建<generator>？或者使用其他约束，让quickCheck 不必筛选一堆失败的条件？

欢迎任何其他一般性建议（尤其是关于 QuickCheck）。

Answer 1

这是制作兼容 QuickCheck 的素数生成器的一种方法（从 http://en.literateprograms.org/Sieve_of_Eratosthenes_(Haskell 窃取 Eratosthenes 的筛子实现）：

import Test.QuickCheck

newtype Prime = Prime Int deriving Show

primes = sieve [2..]
    where
      sieve (p:xs) = Prime p : sieve [x | x <- xs, x `mod` p > 0]

instance Arbitrary Prime where
    arbitrary = do i <- arbitrary
                   return $ primes!!(abs i)

它可以像这样在 QuickCheck 中使用：

prop_primes_dont_divide (Prime x) (Prime y) = x == y || x `mod` y > 0

为了您的使用，您可以在您的资源中将 p 和 q 替换为 (Prime p) 和 (Prime q)。

Answer 2

好的，这就是我所做的。

文件顶部

{-# LANGUAGE NoMonomorphismRestriction #-}

import Test.QuickCheck
import Control.Applicative

问题中给出的所有代码，prop_rsa 除外。那是（显然）大量修改：

prop_rsa = forAll primePair $ \(p,q) ->
           let n = p*q
           in forAll (genUnder n) $ \x  ->
              let e = 3
                  t = (p-1)*(q-1)
                  d = mInverse e t
                  a `powModN` b = modExp a b n
              in p /= q &&
                 rPrime e t ==>
                 x == (x `powModN` e) `powModN` d

primePair 的类型是 Gen (Int, Int)，genUnder 的类型是 Int -> Gen Int。我不确定forAll 背后的魔力是什么，但我很确定这是正确的。我已经对 1) 进行了一些临时调整，以确保在我弄乱条件时它会失败，以及 2) 确保嵌套的 forAll 在测试用例中改变 x 的值。

以下是如何编写这些生成器。一旦我意识到文档中的<generator> 只是意味着Gen a 类型的东西，那就是蛋糕。

genNonzero = (\x -> if x == 0 then 1 else x) `fmap` arbitrary
genUnder :: Int -> Gen Int
genUnder n = ((`mod` n) . abs) `fmap` genNonzero

genSmallPrime = ((\x -> (primes !! (x `mod` 2500))) . abs) `fmap` arbitrary

primePair :: Gen (Int, Int)
primePair = (,) <$> genSmallPrime <*> genSmallPrime

primePair 进行了一些尝试和错误以使我正确；我知道像这样的一些组合器应该工作，但我仍然不像我想要的那样熟悉fmap、<$> 和<*>。我将计算限制为仅从前 2500 个素数中选择；否则它显然想挑选一些需要很长时间才能生成的非常大的东西。

随机注意事项

由于懒惰，除非满足条件，否则不会计算 d = mInverse e t。这很好，因为当条件rPrime e t 为假时它是未定义的。在英语中，整数a 只有在a 和b 互质时才有乘法逆元（mod b）。