如何创建一个以随机顺序重复另一个集合的元素的惰性序列？

Question

我想创建一个重复来自另一个集合的元素的惰性序列。它应该在重复之前生成每个元素之一。并且元素的顺序必须是随机的。

它的行为应该是这样的：

=> (take 10 x)
(B A C B A C A B C C)

这似乎有效：

(def x (lazy-seq (concat (lazy-seq (shuffle ['A 'B 'C])) x)))

但是它使用了两个lazy-seq。有没有办法只使用一个lazy-seq 来编写这种惰性序列？

如果用一个lazy-seq 无法做到这一点，如何生成值？由于我的集合只有三个项目，我希望在第一个块中完全计算内部惰性序列。

在提出上述顺序之前，我尝试了以下顺序：

=> (def x (lazy-seq (concat (shuffle ['A 'B 'C]) x)))

=> (take 10 x)
(C A B C A B C A B C)

我将不胜感激任何解释为什么这个不随机化每批。

Answer 1

只是重复这个序列，然后用 shuffle 函数映射它怎么样？这是一个例子：

(take 10 (mapcat shuffle (repeat ['A 'B 'C])))
;=> (B C A B A C B A C B)

Answer 2

我将不胜感激任何解释为什么这个不随机化每批。

你的(shuffle '[a b c]) 只被评估一次，当序列的开始被实现时，就会一次又一次地使用打乱列表。

这是一个小测试：

user> (defn test-fnc [coll]
        (do (print "boom!")
            (shuffle coll)))
;; => #'user/test-fnc
user> (def x (lazy-seq (concat (test-fnc '[a b c]) x)))
;; => #'user/x
user> (take 10 x)
;; => (boom!b c a b c a b c a b)
user> (take 10 x)
;; => (b c a b c a b c a b)

您也可以改用lazy-cat：

user> (def x (lazy-cat (shuffle '[a b c]) x))
;; => #'user/x

但不会解决你的问题:-)

这是因为lazy-seq:

获取返回ISeq或nil的表达式主体，并生成一个Seqable对象，该对象仅在第一次调用seq时调用主体，并将缓存结果并在所有后续seq调用时返回.

---

如果你根据函数调用重写你的定义：

(defn x [] (lazy-seq (concat (shuffle ['A 'B 'C]) (x))))

它会起作用的：

user> (take 10 (x))
;; => (C B A C A B B A C B)

因为每次调用都会有不同的惰性序列，而不是重复自身的同一个缓存序列。