汇编代码向下滚动屏幕一行清除屏幕中的第一行，然后在按下键时向上滚动一行

Question

我正在尝试向下滚动 1 行，然后向上滚动，但是 a) 我不知道如何测试这段代码 b）我不确定“按下键时”使用哪个中断

非常感谢您的帮助 这是我的代码：

Data_segment_name  segment  para 

firstline db 160 dup(0)




Data_segment_name ends


Stack_segment_name segment para stack



Stack_segment_name ends


Code_segment_name segment 

Main_prog  proc far

    assume SS:Stack_segment_name,CS:Code_segment_name,DS:Data_segment_name

    mov AX,Data_segment_name         ; load the starting address of the data
    mov DS,AX                        ; segment into DS reg. 

    ;code scroll down (clear first line) then scroll back up(restore cleared line)

    mov es,ax                        ;save first line
    lea di,firstline
    mov ax,0b800h
    mov ds,ax
    mov ax,0
    mov si,ax                        
    cld
    mov cx,80
    rep movsw                        ;save ends

    ;now let's scroll down :)

    mov ax,0b800h
    mov es,ax
    mov ax,0
    mov di,ax
    mov ax,160
    mov si,ax
    cld
    mov cx,24*80
    rep movsw

    ;now let's scroll up :)

    int 21h  ;check

    mov ax,160*24
    mov si,ax
    mov ax,160*25
    mov di,ax
    std
    mov cx,24*80
    rep movsw

    ;restore first line

    mov AX,Data_segment_name         ; load the starting address of the data
    mov DS,AX                        ; segment into DS reg. 
    lea si,firstline
    mov ax,0
    mov di,ax
    cld
    mov cx,80
    rep movsw


    mov ax,4c00h                     ; exit program
    int 21h


Main_prog      endp

Code_segment_name   ends
                end Main_prog

Answer 1

广告一）：

测试工具称为“调试器”。我推荐 Turbo Debugger（谷歌）。

广告 b)：

Ralf Brown's interrupt list 和 TechHelp 是很好的参考。一目了然：Int 10h 用于视频，Int 16h 用于键盘，Int 21h 用于 MS-DOS。

您应该切换到简化的段指令.CODE、.DATA、.STACK 和过程编程PROC、ENDP。当您的项目发展壮大时，跟踪它会有所帮助。

例子：

.MODEL small
.STACK 1000h

.DATA
    firstline db 160 dup(0)

.CODE
save_firstline PROC
    push ds
    mov ax, ds
    mov es, ax
    lea di, firstline
    mov ax, 0b800h
    mov ds, ax
    mov ax, 0
    mov si, ax
    mov cx, 80
    rep movsw
    pop ds
    ret
save_firstline ENDP

restore_firstline PROC
    lea si, firstline
    mov ax, 0b800h
    mov es, ax
    mov ax, 0
    mov di, ax
    mov cx, 80
    rep movsw
    ret
restore_firstline ENDP

scroll_up PROC
    call save_firstline
    mov ah, 6               ; http://www.ctyme.com/intr/rb-0096.htm
    mov al, 1               ; number of lines to scroll
    mov bh, 0               ; attribute
    mov ch, 0               ; row top
    mov cl, 0               ; col left
    mov dh, 25              ; row bottom
    mov dl, 80              ; col right
    int 10h
    ret
scroll_up ENDP

scroll_down PROC
    mov ah, 7               ; http://www.ctyme.com/intr/rb-0097.htm
    mov al, 1               ; number of lines to scroll
    mov bh, 0               ; attribute
    mov ch, 0               ; row top
    mov cl, 0               ; col left
    mov dh, 25              ; row bottom
    mov dl, 80              ; col right
    int 10h
    call restore_firstline
    ret
scroll_down ENDP

main PROC
    mov ax, @data
    mov ds, ax

    waitForKey:             ; http://webpages.charter.net/danrollins/techhelp/0229.HTM
        mov   ah, 1
        int   16h
        jnz   gotKey        ; jmp if key is ready
        jmp   waitForKey    ; loop back and check for a key
    gotKey:
        mov ah, 0           ; key is ready, get it
        int 16h             ; now process the key

    cmp ah, 48h             ; <UP>
    jne @F
    call scroll_up
    jmp waitforKey

    @@:
    cmp ah, 50h             ; <DOWN>
    jne @F
    call scroll_down
    jmp waitForKey

    @@:
    cmp al, 1Bh             ; <ESC>
    jne waitForKey

    mov ax, 4C00h
    int 21h

main ENDP

END main