在 Windows 批处理文件中转义用户输入

Question

我有一个 Windows 批处理文件，它接受密码作为用户输入：

SET /P PASSWORD=Password:

此密码可能包含需要转义的字符，例如 !。然后使用CALL 将PASSWORD 变量传递给其他批处理文件

CALL Foo.Bat %PASSWORD%

如何确保特殊字符被转义并作为参数正确传递？例如，如果用户输入!%"£$"，我希望%1 在Foo.bat 中成为!%"£$"。

Answer 1

这是一个不错的挑战，但这是高级批处理技术。
我会在这里使用一种更简单的方法，使用延迟扩展并且不发送内容，只发送变量名。

即使使用特殊字符，这也是绝对安全的。

call foo.bat password

Foo.bat -----------------

Setlocal EnableDelayedExpansion
Echo !password!

编辑：原始问题的解决方案，
这是一种用内容而不是变量名来解决它的方法

在通过 CALL 将内容发送到第二个批处理文件之前发送内容是必要的。
很难使用像CALL foo.bat %preparedVariable%这样的东西
使用CALL foo.bat !preparedVariable!似乎更好
但即便如此，我在 CALL 阶段将插入符号加倍失败了。

但后来我发现了一种在 CALL 阶段之后使用百分比扩展的简单方法。

@echo off

setlocal DisableDelayedExpansion
rem set /p "complex=Complex Input "
set "complex=xx! & "!^&"ab^^ " ^^^^cd%%"

setlocal EnableDelayedExpansion

call :prepareForCallBatch complex PreparedParam
echo Send   =!PreparedParam!#
set complex
echo(
call ShowParam.bat %%PreparedParam%%
exit /b

:: Prepare special characters &|<>"^ for a batch call
:prepareForCallBatch
set "temp=!%~1!"

set "temp=!temp:^=^^!"
set "temp=!temp:&=^&!"
set "temp=!temp:|=^|!"
set "temp=!temp:<=^<!"
set "temp=!temp:>=^>!"
set "temp=!temp:"=^^"!"
set "%~2=!temp!"
exit /b

要查看 ShowParam.bat 中的 real 参数，我使用类似这样的东西
ShowParam.bat

@echo off
setlocal
set prompt=
@echo on
REM # %* #