Delphi - 从字符串创建类

Question

我得到了这样的代码

name := 'Foo';
If name = 'Foo' then
  result := TFoo.Create
else if name = 'Bar' then 
  result := TBar.Create
else if name = 'FooFoo' then
  result := TFooFoo.Create;

有什么办法吗

result := $name.create

或基于变量值创建类的某种方式？

所有类都扩展了同一个基类。

Answer 1

从 Delphi 2010 开始，增强的 RTTI 允许您执行此操作，而无需创建自己的类注册表。

使用RTTI 单元，您有多种选择。

对于无参数构造函数，最简单的方法之一是。

var
 C : TRttiContext;
 O : TObject;
begin
  O := (C.FindType('UnitName.TClassName') as TRttiInstanceType).MetaClassType.Create;
  ...
 end;

这里是一个传递参数的例子，使用TRttiMethod.Invoke()

var
 C : TRttiContext;
 T : TRttiInstanceType;
 V : TValue;

begin
  T := (C.FindType('StdCtrls.TButton') as TRttiInstanceType);
  V := T.GetMethod('Create').Invoke(T.metaClassType,[self]);
  (V.AsObject as TWinControl).Parent := self;
end;

我在RTTI 单元上写了several articles，因为有很多可用选项。

---

更新基于大卫的要求：

比较使用类类型（虚拟构造函数）与TRttiType.Invoke进行构造的用法

类类型方法：（虚拟构造函数）

• 适用于所有版本的 Delphi
• 生成更快的代码
• 在编译时需要祖先的知识。
• 需要类注册表以通过字符串名称查找类（如 RRUZ 提到的）

TRttiType.Invoke() 方法

• 仅适用于 Delphi 2010 或更高版本。
• 较慢的代码
• 实现一个将名称冲突考虑在内的类注册表
• 在编译时要求NO了解祖先。

我个人发现每个都有不同的目的。如果我预先知道所有类型，我会使用类类型方法。

Answer 2

您可以使用GetClass 函数，但在注册类之前必须使用RegisterClass 或RegisterClasses 方法。

GetClass(const AClassName: string): TPersistentClass;

Answer 3

通常的方法是使用虚拟构造函数。 TComponent 就是一个很好的例子，你一定很熟悉。

TComponent 具有以下构造函数：

constructor Create(AOwner: TComponent); virtual;

另一个关键是TComponentClass，它被声明为class of TComponent。

当 VCL 流式传输 .dfm 文件时，它会从 .dfm 文件中读取类的名称，并通过一些我们不需要在这里介绍的过程将该名称转换为变量，ComponentClass 说是类型TComponentClass。然后它可以实例化对象：

Component := ComponentClass.Create(Owner);

这是拥有虚拟构造函数的一大优势，我鼓励您采用相同的方法。

如果您必须使用字符串来识别类，那么您仍然需要提供一个查找例程来将字符串类名转换为类引用。如果方便，您可以挂钩到 TComponent 使用的同一 VCL 机制，即 RegisterClass。

或者，如果您可以将代码中的 name 替换为类引用，那么您可以编写：

type
  TFoo = class
    constructor Create; virtual;
  end;
  TBar = class(TFoo);

  TFooClass = class of TFoo;

var
  MyClass: TFooClass;

...

MyClass := TFoo;
result := MyClass.Create;//creates a TFoo;

MyClass := TBar;
result := MyClass.Create;//creates a TBar;