VB.net - 查看远程文件是否存在

Question

我有一个函数可以在传递 URL 后检查远程文件是否存在。假设它不存在，该函数将返回 0 以在另一个子中使用。这是我所拥有的：

Public Function RemoteFileExists(ByVal fileurl As String) As Integer
    Dim request As FtpWebRequest = DirectCast(WebRequest.Create(fileurl), FtpWebRequest)
    request.Method = WebRequestMethods.Ftp.GetFileSize
    Dim response As FtpWebResponse = DirectCast(request.GetResponse(), FtpWebResponse)
    If response.StatusCode = FtpStatusCode.ActionNotTakenFileUnavailable Then
        RemoteFileExists = 0
        Exit Function
    End If
    Dim fileSize As Long = response.ContentLength
    MsgBox(fileSize)
    If fileSize > 0 Then
        RemoteFileExists = 1
    Else
        RemoteFileExists = 0
    End If
End Function

当我运行应用程序并故意提供一个不存在的 URL 时，Visual Studio 给了我 System.Net.WebException 未处理。 Message=远程服务器返回错误：(550) 文件不可用（例如，找不到文件，无法访问）。

我假设“if response.StatusCode...”会处理这个问题，而不是关闭程序。

任何帮助表示赞赏。

DWM

Answer 1

首先，您应该从Integer 切换到Boolean，因为无论如何您只返回1 或0。 Boolean 可以是 True 或 False。

其次，您应该将所有内容包装在 Try/Catch 块中以处理可能发生的任何错误。在Try/Catch 中包装代码可以捕获大多数错误（最极端的错误除外），并将其放在可能引发错误的代码周围，可以避免应用程序因更简单的错误而崩溃。

最后，您应该使用Return <value> 而不是RemoteFileExists = <value>，因为Return 将返回所需的值并退出函数。

示例实现：

Public Function RemoteFileExists(ByVal fileurl As String) As Boolean
    Try
        Dim request As FtpWebRequest = DirectCast(WebRequest.Create(fileurl), FtpWebRequest)
        request.Method = WebRequestMethods.Ftp.GetFileSize
        Dim response As FtpWebResponse = DirectCast(request.GetResponse(), FtpWebResponse)
        If response.StatusCode = FtpStatusCode.ActionNotTakenFileUnavailable Then
            Return False 'Return instead of Exit Function
        End If
        Dim fileSize As Long = response.ContentLength
        MsgBox(fileSize)
        If fileSize > 0 Then
            Return True
        Else
            Return False
        End If
    Catch ex As Exception 'Catch all errors
        'Log the error if you'd like, you can find the error message and location in "ex.Message" and "ex.StackTrace".
        MessageBox.Show("An error occurred:" & Environment.NewLine & ex.Message & Environment.NewLine & ex.StackTrace, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Return False 'Return False since the checking failed.
    End Try
End Function

在Catch 块中，ex.Message 是错误消息，ex.StackTrace 是代码中发生错误的位置。