使用VBS运行带参数的程序

Question

我是一个完整的 vbs 新手，试图执行使用 vbscript 运行单个程序（带参数）的所谓简单任务。

程序的路径是： C:\Program Files (x86)\SpeedyFox\speedyfox.exe 并且必须与之配套的参数开关是： /Firefox:C:\Program Files\Firefox\Data\profile

如果我将两个部分都用引号引起来（由于它们的路径中有空格），它会给出以下组合的单个命令：

"C:\Program Files (x86)\SpeedyFox\speedyfox.exe" "/Firefox:C:\Program Files\Firefox\Data\profile"

如果我将其粘贴到 Start > Run 中，它会完全按照我的意愿工作。

我只是想通过 vbs 脚本实现相同的功能，而不是手动粘贴到 运行 框中。

我确实不希望命令在 CMD 控制台中运行（正如此处的其他问题所问的那样）。我要做的就是让"C:\Program Files (x86)\SpeedyFox\speedyfox.exe" "/Firefox:C:\Program Files\Firefox\Data\profile" 使用下面脚本的 shell.ShellExecute 行。

Set objShell = Wscript.CreateObject ("Wscript.shell")
set shell=CreateObject("Shell.Application")
shell.ShellExecute  ** WHAT DO I PUT HERE? **
set shell=nothing

但尽我所能，我只是不断收到 WSH“Expected end of statement”错误消息。

Answer 1

1.First：我建议你养成使用这个报价功能的习惯 方便您在这些情况下引用变量！

2.第二：你应该使用MsgBox或Wscript.echo来显示 并轻松调试您的变量！

Wscript.echo DblQuote("Hello World !")
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function

所以，我下载了这个应用程序 (speedyfox.exe)，并在我的 Windows 10 (32bits)

上对其进行了测试

所以，这是我测试过的，它对我来说就像一个魅力：

Option Explicit
Dim objShell,MyCommand,strProgramFiles,SpeedyFoxfile,Title
Title = "Execute SpeedyFox in Commandline"
Set objShell = CreateObject("Shell.Application")
strProgramFiles = GetProgramFilesPath()
SpeedyFoxfile = strProgramFiles & "\SpeedyFox\speedyfox.exe"
MsgBox "Without Double Quotes" & vbCrlf & SpeedyFoxfile,vbInformation,Title
MsgBox "With Double Quotes" & vbCrlf & DblQuote(SpeedyFoxfile),vbInformation,Title
MyCommand = "CD /D "& DblQuote(strProgramFiles &"\SpeedyFox\") &"&"& DblQuote(SpeedyFoxfile) & " " & DblQuote("/Firefox:default") & " " & DblQuote("/Chrome:Default")
MsgBox MyCommand,vbInformation,Title
Call Execute(MyCommand) 
'-----------------------------------------
Function Execute(StrCmd)
   Dim ws,MyCmd,Result
   Set ws = CreateObject("wscript.Shell")
   MyCmd = "CMD /K " & StrCmd & ""'
   Result = ws.run(MyCmd,1,True)
   Execute = Result
End Function
'-----------------------------------------
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'-----------------------------------------
Function GetProgramFilesPath()
Dim ws,OsType,strProgramFiles
Set ws = createObject("WScript.Shell")  
OsType = ws.RegRead("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment\PROCESSOR_ARCHITECTURE")    
    If OsType = "x86" then    
        strProgramFiles = ws.ExpandEnvironmentStrings("%PROGRAMFILES%")  
    elseif OsType = "AMD64" then   
        strProgramFiles = ws.ExpandEnvironmentStrings("%PROGRAMFILES(x86)%")  
    end if 
GetProgramFilesPath = strProgramFiles
End Function
'-----------------------------------------

Answer 2

叹息，让我想起了我的 vbscript 日子，现在我使用 Ruby，它就像简单一样

´my_shell_command params´

但是，回到你的问题：使用 ShellExecute 的最短方法是

CreateObject("Shell.Application").ShellExecute "application", "parameters", "dir", "verb", window

有关参数的说明，请参阅this 文档。

编辑： 您必须注意引号，它们也需要使用两个引号传递给 shell

例如CreateObject("Shell.Application").ShellExecute "C:\Program Files (x86)\SpeedyFox\speedyfox.exe", """/Waterfox:C:\Program Files\Waterfox\Data\profile"""