Bison 非关联优先规则

Question

我试图通过定义非关联优先级来强制执行一些解析错误。 这是我的语法文件的一部分：

Comparison :
    Value ComparisonOp Value 
    {
        $2->Left($1);
        $2->Right($3);
        $$ = $2;
    } 
    ;

应该解析像 1 = 2 这样的表达式，但是语法中不允许像 1 = 2 = 3 这样的表达式。为了适应这一点，我尝试使我的运算符非关联，如下所示：

%nonassoc NONASSOCIATIVE
.
.(rest of the grammar)
.
Comparison :
    Value ComparisonOp Value %prec NONASSOCIATIVE
    {
        $2->Left($1);
        $2->Right($3);
        $$ = $2;
    } 
    ;

1 = 2 = 3 仍然通过，谁能告诉我我做错了什么？

Answer 1

您需要设置ComparisonOp 标记的关联性。要么

%nonassoc ComparisonOp NONASSOCIATIVE

如果ComparisonOp 是令牌或类似的东西

%nonassoc '=' '<' '>' NOT_EQUAL GREATOR_OR_EQUAL LESS_OR_EQUAL NONASSOCIATIVE

如果您有多个令牌并且ComparisonOp 是扩展至其中任何一个的规则

---

作为一个具体示例，以下内容与您的要求完全一样：

%{
#include <stdio.h>
#include <ctype.h>
int yylex();
void yyerror(const char *);
%}
%nonassoc '=' '<' '>' CMPOP
%left '+' '-' ADDOP
%left '*' '/' '%' MULOP
%token VALUE
%%
expr: expr cmp_op expr %prec CMPOP
    | expr add_op expr %prec ADDOP
    | expr mul_op expr %prec MULOP
    | VALUE
    | '(' expr ')'
    ;
cmp_op: '=' | '<' | '>' | '<' '=' | '>' '=' | '<' '>' ;
add_op: '+' | '-' ;
mul_op: '*' | '/' | '%' ;
%%
int main() { return yyparse(); }
int yylex() {
    int ch;
    while(isspace(ch = getchar()));
    if (isdigit(ch)) return VALUE;
    return ch;
}
void yyerror(const char *err) { fprintf(stderr, "%s\n", err); }

因此，如果您遇到其他问题，请尝试发布 MVCE 以显示您遇到的实际问题...