宏数值比较

Question

我正在尝试比较宏中的两个数值。 但我不断收到以下消息：

ERROR: A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was: 0.2
ERROR: The %TO value of the %DO I loop is invalid.
ERROR: A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was: 0.05
ERROR: The %BY value of the %DO I loop is invalid.
ERROR: The macro FAIL will stop executing.

我的代码如下：

%macro fail;
      %do i=0 %to 0.2 %by 0.05;
          data failcrs;
              set fail;
              if f_p>=input(&i, 8.) then output;
          run;
      %end;
%mend failcrs;

f_p 是一个数值变量。

我的代码有什么问题？请帮忙。

非常感谢！

Answer 1

宏代码（%if、%until、%while 等）中的条件测试使用仅执行整数运算的 %eval() 宏函数。这包括在 %do-%to-%by 循环中完成的增量和测试。

要使用浮点运算，您需要使用%sysvalf() 宏函数。

您可以将自己的增量编码到循环计数器。

%let i=0;
%do %while( %sysevalf( &I <= 0.2 ) );
   ...
   %let i=%sysevalf(&i + 0.05);
%end;

或者将循环计数器设为整数并使用另一个宏变量来保存分数。

%do j=0 %to 20 %by 5 ;
   %let i=%sysevalf(&j/100);
   ...
%end;

Answer 2

您有几个问题。 宏循环更适用于整数，但一个简单的解决方法是使用 %DO %UNTIL 循环。

1. %MEND 上的名称与 %MACRO 上的名称不同
2. %DO %I 循环的值无效。

3. 非唯一的数据集名称，表示输出会覆盖自身。

   *fake data to work with;  
   data fail;
       do f_p=0 to 0.2 by 0.01;
           output;
       end;
   run;
   
   %macro fail;
       %let i=0;
         %do %until(&i = 0.2); /*2*/
             data failcrs_%sysevalf(&i*100); /*3*/
                 set fail;
                 if f_p>=&i then output;
             run;
             %let i = %sysevalf(&i + 0.05);
         %end;
   %mend fail; /*3*/
   
   *test macro;
   %fail;
   

cmets 中的数字与发现的问题一致。

Answer 3

尝试使用 best32。但是，当您的数据集被每个循环覆盖时，您为什么要循环。请检查以下每个步骤的日志。正如 cmets 中的@Reeza 在下面解释的那样，您甚至没有输入语句 选项印记；

   /* do this*/
    %macro fail;
   %let i =15;
    data failcrs;
          set sashelp.class;

          if age lt input(&i, best32.)  then output;
      run;
   %mend fail;

  %fail

   /* dataset overwritten every time to finally pick up 15 as value check in the log*/
   %macro fail1;
   %do i = 1 %to 15;
    data failcrs1;
          set sashelp.class;

          if age lt input(i, best32.) then output;
      run;
  %end;
 %mend fail1;

%fail1

Answer 4

%macro fail;
        %let i=0;
        %do %until(&i = 0.2);
            data failcrs; 
                set crse_grade_dist_fail;
                if f_p>=&i then output;
                run;

        proc sql;
            create table count_failclass as
            select strm, count(class_nbr) as numfclass_%sysevalf(&i*100)
            from failcrs
            group by strm;
        quit;

        proc sql;
            create table failfaculty as
            select strm, instructor_id, instructor, count(class_nbr) as numfclass
            from failcrs
            group by strm, instructor_id, instructor;
        quit;

        proc sql;
            create table count_failfaculty as
            select strm, count(instructor) as numffaculty_%sysevalf(&i*100)
            from failfaculty
        group by strm;
        quit;

        data count_class_faculty;
            set count_class_faculty;
            set count_failclass;
            set count_failfaculty;
        run;

        %let i = %sysevalf(&i + 0.05);
    %end;
%mend fail;

好在我的数据没有 f_p=0，它们都大于零。因为我只想统计失败的课程。

Answer 5

文档是为阅读而编写的，对“SAS 9.4 Macro Do”的简单搜索应该可以解释这一切 - start、stop 和 by 是整数 - 整数在某种意义上说，无论宏源表达式在它们的位置进行计算还是隐式计算在需要的时候显式地转换成一个整数。

您编写的宏有点奇怪。它将生成多个数据步骤，这些步骤都会覆盖相同的数据集。您可能希望专注于先不编写宏代码，然后在需要提交重复的样板代码时转向它。编写好的宏代码意味着您必须考虑“这是否会生成适当的源代码以及这些宏语句在其解析范围内会产生什么副作用”

%DO, Iterative Statement

语法

%DO 宏变量=开始 %TO 停止 增量 em>>;

  文本和宏语言语句

%END;

必填参数

宏变量

• 命名宏变量或生成宏的文本表达式 变量的名称。它的价值作为一个指标来确定 %DO 循环迭代的次数。如果指定了宏变量 由于索引不存在，宏处理器在 局部符号表。

• 您可以更改 处理过程中的索引变量。例如，使用条件 将索引变量的值设置为超出停止值的处理 满足某个条件时的值结束循环的处理。

开始停止

• 指定整数或生成整数的宏表达式 控制宏的部分之间的次数 处理迭代的 %DO 和 %END 语句。

• 第一次 %DO 组迭代，宏变量等于开始。作为加工 继续，宏变量的值变化的值 递增直到宏变量的值超出 start 和 stop 包含的整数。

增量

• 指定一个整数 （除 0 以外）或生成整数的宏表达式 在每次迭代中添加到索引变量的值 环形。默认情况下，增量为 1。增量在 循环的第一次迭代。因此，您不能将其更改为 循环迭代。