如何在 Clojure 中获取参数名称？

Question

我想从函数内部获取在函数外部定义的 var 的名称。该名称应该是我在原始定义范围内使用的名称，而不是我实际尝试使用该名称的任何嵌套绑定。

所以我想做一些类似（学术例子）的事情：

(defn f1 [x1] (println "hello, you passed var name >>" (get-var-name x1) "<<")
(defn f2 [x2] (f1 x2))
(defn f3 [x3] (let [zzz x3] (f2 zzz))
(def my-var 3.1414926)
(f3 my-var)
user> hello, you passed var name >>my-var<<

我可以根据我找到的一些东西来做这个宏：

(defmacro get-var-name [x]
  `(:name (meta (var ~x))))

这在例如从 REPL 调用时有效，但是当从“内部”范围调用时编译器会阻塞，例如

(defn another-func [y]
  (get-var-name y))

编译器说“无法解析 var y”。 (macroexpand...) 表明它试图在当前命名空间中查找局部变量 y，而不是当前命名空间中的原始变量。我认为(var...) 仅查找命名空间变量，因此这会阻止宏在函数或其他绑定（例如let）中工作。

我认为我不得不从定义变量的同一范围内手动获取变量名，并将其作为额外参数传递。有没有更优雅的方法通过绑定链将 var 名称信息传递到使用它的位置？那会很糟糕。

谢谢

Answer 1

不可能获得在外部作用域中使用的变量的名称​​在函数内 - 函数只接收在运行时作为参数传递的值，不是 var 本身。

您唯一可能做的就是在每个级别使用宏而不是函数。这允许您在编译时通过不同的宏传递 var 本身：

(defmacro f1 [x1] `(println "hello, you passed var name >>" ~(str x1) "<<"))
(defmacro f2 [x2] `(f1 ~x2))
(defmacro f3 [x3] (let [zzz x3] `(f2 ~zzz)))

(f3 my-var)
=> hello, you passed var name >> my-var <<

这很丑 - 你当然不想为了获得这个功能而用宏编写所有代码！尽管在某些特殊情况下它可能是有意义的，例如如果您正在创建某种基于宏的 DSL。

Answer 2

您可以使用#'阅读器宏将实际的var而不是var解析的值传递给函数，如下所示：

user=> (defn f1 [x1] (println "hello, you passed var name >>" (:name (meta x1)) "<<"))
#'user/f1
user=> (defn f2 [x2] (f1 x2))
#'user/f2
user=> (defn f3 [x3] (let [zzz x3] (f2 zzz)))  
#'user/f3
user=> (def my-var 3.1414926)
#'user/my-var
user=> (f3 #'my-var)
hello, you passed var name >> my-var <<

如果您希望将值绑定到 var，您可以使用 var-get 函数来执行此操作。

Answer 3

为什么不直接将(get-var-name _symbol-here_) 传递给您希望在主体内使用var 名称的函数？例如，使用与您在上面给出的 get-var-name、f2、f3 和 my-var 完全相同的定义（但稍微更改 f1）：

(defmacro get-var-name [x]
  `(:name (meta (var ~x))))
(defn f1 [x1] (println "hello, you passed var name >>" x1 "<<"))
(defn f2 [x2] (f1 x2))
(defn f3 [x3] (let [zzz x3] (f2 zzz)))
(def my-var 3.1414926)
=> (f3 (get-var-name my-var))
hello, you passed var name >> my-var <<
=> nil

也许有时候，你也想在函数体中引用符号所引用的值。例如，假设在f1 中，您还想打印出该变量名称引用的值。你可以这样做：

(defn f1 [x1] (println "hello, you passed var name >>" x1 "<<"
                       "\nwhich refers to value >>" @(resolve x1) "<<"))
=> (f3 (get-var-name my-var))
hello, you passed var name >> my-var << 
which refers to value >> 3.1414926 <<
=> nil

注意@(resolve x1)——这是返回my-var所指的值的东西（而my-var又是x1所指的值）。

另外，我想提一下，当传递给它的参数不是符号或者是符号但当前未绑定到值时，您当前的 get-var-name 实现将抛出异常。这是你想要的行为吗？

如果我的建议不能回答您的问题，那么您似乎不想有将 (get-var-name _symbol-here_) 传递给可能最终使用 var 名称的函数，而是出于某种原因，真的希望能够从函数体内执行(get-var-name ...)。如果是这种情况，为什么您希望能够那样做？或者，如果您觉得我出于其他原因没有回答您的问题，那是什么原因？