Racket 中的嵌套宏

Question

我希望能够编写这样的嵌套表达式：

(AND/OR expr1 op1 expr2 AND/OR expr3 op2 expr4 and so on)

AND/OR 本质上是 AND 或 OR。但我希望能够写出无限数量的它们。我正在使用define-syntax 来尝试实现这一点，但我不确定如何接受无限数量的嵌套表达式。

不要介意我的例子中的 expr 和 op，这部分我可以自己处理。我只想知道如何接受无限嵌套。

例子：

(SELECT somecolumns
FROM sometable
WHERE something
AND/OR something
AND/OR (something AND/OR something)
AND/OR ...)

Answer 1

正如 Asumu 所说，通常处理 s 表达式更简单，至少为了确保正确的运算符优先级，但对于一些简单的情况，syntax-rules（和syntax-parse 和 co）的模式匹配使这很容易，使用剩余参数和递归匹配：

#lang racket
(define-syntax parse-args
  (syntax-rules (AND) ; treat AND as a literal
    [(_)
     ; no more argument, return value:
     '()]

    [(_ (arg1 AND in-rst ...))
     ; Composed argument found, call parse-args recursively:
     (parse-args arg1 AND in-rst ...)]

    [(_ arg1 AND rst ...)
     ; AND operator found, parse left side and rest
     (list 'and
           ; parse the argument (may be composed or not):
           (parse-args arg1)
           ; then parse the rest of the arguments:
           (parse-args rst ...))]

    [(_ arg)
     ; in case the argument is not composed or does not contain AND, don't parse it
     arg]))

;; TESTS:
(parse-args 'a AND ('b AND 'bb) AND 'c AND 'f)
; -> '(and a (and (and b bb) (and c f)))

(parse-args 'a AND ('b AND 'bb))
; -> '(and a (and b bb))

但是，请注意，上面的代码在添加其他运算符时可能变得不切实际。

编辑： 与 select 宏一起使用：

(define-syntax SELECT
  (syntax-rules (FROM WHERE)
    [(_ select FROM from WHERE where ...)
     (list 'Select select 'From from 'Where (parse-args where ...))]))

; TEST:
(SELECT 'somecolumns
FROM 'sometable
WHERE 'something1
AND 'something2
AND ('something3 AND 'something4)
AND 'blop)
; -> 
#;'(Select
    somecolumns
    From
    sometable
    Where
    (and something1
         (and something2
              (and (and something3 something4) blop))))

同样，模式匹配允许在正确的点切割列表以获得其余参数