Nasm 预处理器 - 通过变量的地址参数

Question

我需要编写很多推送不同字符的push 指令。我想为此使用宏。这是我到目前为止所做的：

%macro push_multi 1-*       ; Accept between 1 and ∞ arguments
    %assign i 1
    %rep %0                 ; %0 is number of arguments
        push %{i}
        %assign i i+1
    %endrep
%endmacro

push_multi 'a', 'b', 'c'    ; push 'a' then push 'b' then push 'c'

但是nasm -E 的结果是：

push %i
push %i
push %i

我想要这个：

push 'a'
push 'b'
push 'c'

如何使用assign 创建的变量来处理宏的第 n 个参数？

Answer 1

使用%rotate 1，您可以将宏参数列表向左旋转1 个元素。这有效地将列表中的下一个元素放在开头。列表中的第一个元素始终可以引用为%1。将它放在%rep %0 循环中将允许您遍历宏参数列表中的所有元素。 NASM documentation for %rotate 是这样说的：

%rotate 使用单个数字参数（可能是表达式）调用。宏参数向左旋转了那么多地方。如果 %rotate 的参数为负数，则宏参数向右旋转。

在您的情况下，这应该可以：

%macro push_multi 1-*       ; Accept 1 or more arguments
    %rep %0                 ; %0 is number of arguments pass to macro
        push %1
        %rotate 1           ; Rotate to the next argument in the list
    %endrep
%endmacro

如果您想反向执行列表，可以使用-1 向相反方向旋转，然后先执行%rotate：

%macro push_multi 1-*       ; Accept 1 or more arguments
    %rep %0                 ; %0 is number of arguments pass to macro
        %rotate -1          ; Rotate to the prev argument in the list
                            ; If at beginning of list it wraps to end of list 
        push %1
    %endrep
%endmacro