如何使用 VBA 宏将图表添加到特定单元格

Question

我想将使用 VBA 创建的图表定位到特定的单元格位置。这是我的代码

Private Sub CommandButton1_Click()
ActiveSheet.Shapes.AddChart.Select
ActiveChart.SetSourceData Source:=Range("'Chart'!$A$1:$L$2")
ActiveChart.ChartType = xlLineMarkers
Dim cht As Chart
Dim ser As Series
Set cht = ActiveChart
Set ser = cht.SeriesCollection(1)
ser.Format.Line.Visible = msoFalse
ser.Format.Line.Visible = msoTrue
ser.Format.Line.ForeColor.RGB = RGB(26, 46, 74)
ser.Format.Fill.ForeColor.RGB = RGB(26, 46, 74)
With Worksheets("Chart").ChartObjects(1).Chart
.HasTitle = True
.ChartTitle.Text = Sheets("Chart").Range("B4")
End With
Dim Srs As Series
Set Srs = ActiveChart.SeriesCollection(1)
Srs.Name = "Desired Name"
Dim ChartObj As Object
For Each ChartObj In Sheets("Chart").ChartObjects
ChartObj.Chart.Location xlLocationAsObject, "Factsheet"
Next ChartObj
End Sub

请问有什么办法可以解决这个问题吗？

Answer 1

如果您使用ChartObjects.Add(Left, Top, Width, Height) 方法。它允许您以点为单位指定图表位置。

例如：

Private Sub CommandButton1_Click()
   Dim cht As ChartObject
   Dim ser As Series
   Set cht = ActiveSheet.ChartObjects.Add(20, 20, 400, 150)
   With cht.Chart
    .ChartType = xlLineMarkers
    .HasTitle = True
    .ChartTitle.Text = Worksheets("Chart").Range("B4")
    .SetSourceData Source:=Worksheets("Chart").Range("$A$1:$L$2")
   End With
   Set ser = cht.Chart.SeriesCollection(1)
   With ser.Format
    .Line.Visible = msoTrue
    .Line.ForeColor.RGB = RGB(26, 46, 74)
    .Fill.ForeColor.RGB = RGB(26, 46, 74)
  End With
End Sub

详情请见下文： https://msdn.microsoft.com/en-gb/library/office/ff197613.aspx