FIRST INSTANCE 的 Excel VBA 地址，而不是值的每个位置的地址

Question

我在工作簿的 Sheet1 中列出了一些员工编号。工作簿中还有一些其他工作表（我们将这些工作表称为 A、B、C、D 等），其中包含员工编号和一些信息（可能是工作日期）。如果在工作表 A 中找到员工编号，则它不会出现在任何其他工作表中，但它可能会在工作表 A 中出现多次。

我编写了一些 VBA，它将在所有其他工作表中查找 Sheet1 中列出的员工编号，并返回找到该员工编号的单元格位置。员工编号列在 A 列中，从 A2 开始，它列出了在员工编号右侧找到编号的位置。 How Sheet1 looks Sheet "A"

现在，当我运行我的 VBA 宏时，它会列出找到该员工编号的所有单元格位置，但我想要它只给我该员工编号的第一个实例的单元格位置.然后，转到 Sheet1 的 A 列中列出的下一个员工编号。这是我目前拥有的 VBA。

Sub makeMySearch()
Dim ws As Worksheet, lastrow As Long

For Each cell In Sheets("Sheet1").Range("A2:A" & Sheets("Sheet1").Range("A1").End(xlDown).Row)
    recFound = 0

    For Each ws In ThisWorkbook.Worksheets
        If ws.Name <> "Sheet1" Then
            lastrow = Sheets(ws.Name).Range("A1").End(xlDown).Row
            For Each cell2 In Sheets(ws.Name).Range("A1:A" & lastrow)

                If InStr(cell2.Value, cell.Value) <> 0 Then

                    recFound = recFound + 1
                    cell.Offset(0, recFound) = Split(cell2.Address, "$")(1) & Split(cell2.Address, "$")(2)

                End If
            Next cell2
        End If
    Next ws
Next cell

MsgBox "Done Finding!"

End Sub

Answer 1

如果您说 Sheet1 上的 A 列是标题行并且数据从第 2 行开始，您只需编辑以下行：

dat = .Range(.Cells(1, 1), .Cells(2, 1).End(xlDown)).Value

成为：

dat = .Range(.Cells(2, 1), .Cells(2, 1).End(xlDown)).Value

Answer 2

此方法将在第一次找到时停止（通过Exit For）

它还展示了一种更有效的方法，而不是循环每张纸上的所有单元格

Sub makeMySearch()
    Dim cell  As Range, cell2 As Range
    Dim ws As Worksheet, lastrow As Long, recFound As Long
    Dim rw As Variant
    Dim dat As Variant, i As Long

    With Worksheets("Sheet1")
        dat = .Range(.Cells(2,1), .Cells(.Rows.Count,1).End(xlUp)).Value
        For i = 1 To UBound(dat, 1)
            For Each ws In ThisWorkbook.Worksheets
                If ws.Name <> "Sheet1" Then
                    rw = Application.Match( dat(i, 1) , ws.Columns(1), 0)
                    If Not IsError(rw) Then
                        .Cells(i+1, 2) = "A" & rw
                        ' Option: show Sheet name and cell
                        '.Cells(i+1, 2) = ws.Name & "!A" & rw
                        Exit For
                    End If
                End If
            Next ws
        Next
    End With

    MsgBox "Done Finding!"
End Sub