扩展宏导致 KeyError

Question

使用以下（简化的）代码：

(setv agnostic-manager-installers {})

(defmacro alias-assign [am &rest aliases]
    (for [alias aliases] (assoc
        agnostic-manager-installers
        (str alias)
        (-> (globals) (get (str am)) (get "install")))))

(setv brew {
    "prefix" "/home/linuxbrew/.linuxbrew/"
    "install" (defn brew [] (run
                "curl -fsSL https://raw.githubusercontent.com/Homebrew/install/HEAD/install.sh | sudo bash"
                :shell True))
})

(alias-assign brew brew homebrew home-brew linuxbrew linux-brew)

我收到以下错误：

Traceback (most recent call last):
  File "/home/shadowrylander/.local/syvl/python/hy/bin/hy", line 8, in <module>
    sys.exit(hy_main())
  File "/usr/lib/python3.9/contextlib.py", line 137, in __exit__
    self.gen.throw(typ, value, traceback)
  File "<stdin>", line 9, in alias_assign
hy.errors.HyMacroExpansionError: 
  File "<stdin>", line 20
    (alias-assign brew brew homebrew home-brew linuxbrew linux-brew)
    ^--------------------------------------------------------------^
expanding macro alias-assign
  KeyError: 'brew'

我认为宏不应该在编译时评估参数，如果我正确读取错误（我认为我不是）？基本上，我想不在提供给alias-assign 的每个别名周围写上双引号，这就是我使用宏的原因。

Answer 1

这里有一些更简单的代码会产生同样的错误：

(setv brew 1)

(defmacro m []
  (get (globals) "brew"))

(m)

也许问题现在更加明显：尝试在宏扩展期间访问全局变量 brew 不起作用，因为在发生宏扩展时，brew 在编译期间不存在。如果您只说brew 而不是(get (globals) "brew")，则会出现同样的问题，使用NameError 而不是KeyError。在任何情况下，(setv brew 1) 表单在运行时才会被评估。解决这个问题的一种方法是改用(eval-when-compile (setv brew 1))。这使得评估发生得更早。

一个更广泛的问题是，由于宏扩展，您似乎正在执行实际上想要返回的代码。毕竟，宏的主体是for，所以它总是会返回None。对比以下代码，它使用引用和取消引用来生成表单并返回它们（并使用更新的语法）：

(setv agnostic-manager-installers {})

(defmacro alias-assign [am #* aliases]
  `(do ~@(gfor
    alias aliases
    `(setv (get agnostic-manager-installers ~(str alias))
      (get ~am "install")))))

(setv brew (dict
  :prefix "/home/linuxbrew/.linuxbrew/"
  :install "placeholder"))

(alias-assign brew brew homebrew home-brew linuxbrew linux-brew)

(print (hy.repr agnostic-manager-installers))

结果是：

{"brew" "placeholder"  "homebrew" "placeholder"  "home-brew" "placeholder"  "linuxbrew" "placeholder"  "linux-brew" "placeholder"}