【问题标题】:operand size mismatch for `imul ''imul' 的操作数大小不匹配
【发布时间】:2023-03-17 14:14:01
【问题描述】:

虽然我只使用 long 进行乘法,但不知道为什么operand size is wrong:

.type _square, @function
_square:
pushl %ebp
movl %esp, %ebp
subl $4, %esp #room for the local variable

movl 8(%ebp), %ecx #the first and only argument
movl $1, %eax

_finding_loop:
incl %eax
movl %eax, %ebx
imull %ebx, -4(%ebp) #storing the result in local var
cmpl -4(%ebp), %ecx #compare with the argument
je _found #epilogue and returning
jmp _finding_loop

【问题讨论】:

  • 你的意思可能是 imull %ebx,存储结果需要额外的 movl
  • 我不明白。第一个操作数应该是我想乘以 %eax 的内容(例如,我想乘以 %ecx 或 %ebx)——这是第一个操作数。我应该去哪里存储结果。如果我没有记错的话。那你到底是什么意思?
  • AT&T 语法颠倒了。第一个操作数是源,第二个操作数是目标。 Intel:“目标操作数是通用寄存器,源操作数是立即数、通用寄存器或内存位置”。您不能将内存 (-4(%ebp)) 定义为目标。
  • 没有目标是内存的 imul 指令——所以最后一个操作数(目标和第一个源)必须是寄存器。第一个操作数(第二个源)可以是寄存器或内存。
  • 只有一个操作数felixcloutier.com/x86/imul时,imul的目的地只能是内存

标签: assembly x86 att


【解决方案1】:

这是一个虚假的错误信息。问题不是操作数大小,而是imul 的目标必须是一个寄存器。 https://www.felixcloutier.com/x86/imul。只有源可以是内存。

(AT&T 语法为op src, dst,与使用 Intel 语法的 Intel 手册相反。)

当您遇到不合理的错误时,您应该查阅 ISA 参考并确保您想要的指令实际上是可编码的:汇编程序打印无法正确解释原因的错误消息并非闻所未闻无法汇编指令。但通常它要么是不明确的操作数大小,要么是您想要的编码不存在。

也许 GAS 内部将内存目标视为具有未知或某种随机大小,并且没有像 add %reg, (mem) 那样暗示该操作数的大小。可能因为imul 没有内存目标表单。


像普通人一样将局部变量保存在寄存器中。只需要在寄存器用完时将变量溢出到堆栈上的一个槽。

EAX、ECX 和 EDX 在正常调用约定中被调用破坏,因此您可以在不保存/恢复的情况下使用它们。 (EBX 是保留调用的,因此您的函数已经通过破坏其调用者的 EBX 值而违反了调用约定。)


cmpl -4(%ebp), %ecx #compare with the argument
je _found #epilogue and returning
jmp _finding_loop

永远不要在jmp 上写条件分支。而是使用jne top_of_loop 来保持循环或失败。


IDK 你的循环应该做什么。你没有初始化你的内存目的地。你认为它会将ebx*ebx 的结果存储到内存中吗?如果是这样,为什么首先将 EAX 复制到 EBX?

看起来你正在搜索一个数字的 sqrt,而不仅仅是一个数字的平方,所以函数名称很奇怪。如果是这样,您可能希望jb 作为循环条件以在x*x < target 时继续循环,并在循环后排序等于与上述。 (如果函数调用的 arg 不是一个完美的正方形。)

.globl find_exact_sqrt
find_exact_sqrt:

    mov   4(%esp), %ecx    # target number
    mov   $1, %eax         # start searching from 2*2=4

.Lloop:       # file-local label, not exported in the symbol table
                         # do {
    inc   %eax
    mov   %eax, %edx
    imul  %edx, %edx       # eax squared
    cmp   %ecx, %edx
    jb    .Lloop         # }while(i*i < target); // unsigned

    ret

【讨论】:

  • 谢谢。当我从 c 切换时,我只学习了几天 GAS。但是,在上面的代码中,我不明白你为什么不存储游览基指针 - 因为我学习了这样的函数约定:pushl %ebp\nmovl %esp, %ebp\nmovl 8(%ebp), %ecx #target number。您只是从堆栈指针 4(%esp) 中获取目标编号,而不是从基指针 8(%ebp),为什么会这样?持有基指针不是更好的方向吗?
  • @Herdsman:编译器启用-fomit-frame-pointer -O1 和更高版本的原因相同:性能。无需浪费 EBP 持有帧指针。由于我的版本不需要任何堆栈空间,因此人类读者可以通过 ESP 访问返回地址上方堆栈槽中的一个 arg。 (我宁愿使用带有寄存器参数的调用约定,例如 GCC 的 32 位 regparm。或者更好的是 x86-64 System V。但我保持它与问题中的函数兼容。)
猜你喜欢
  • 1970-01-01
  • 2017-02-23
  • 1970-01-01
  • 2018-02-11
  • 1970-01-01
  • 1970-01-01
  • 2021-01-31
  • 2011-04-18
  • 2020-03-21
相关资源
最近更新 更多