为什么我的分支指令没有跳转到给定的地址？

Question

我目前正在学习逆向工程，因此我需要学习汇编。代码运行良好，但在JE 和JNE 指令上出现错误。更具体地说：我正在做一个绕道钩子作为练习，程序崩溃了，因为它跳转到了错误的地址。

我想写这个，但是编译器给了我一个错误（LNK2016）：

JE 0x123 (0x123 example address)

我通过写作解决了这个问题：

JE short 0x123

完整功能代码：

my_hook:
    push rbp        
    mov rbp, rsp

    mov dword [rcx + 0x18], 99   

    test rcx, rcx
    je 0x7FF7847902EE
    lock dec dword [rcx + 0x08]
    jne 0x7FF7847902EE
    mov rcx, [rsp + 0x30]

    leave   
    ret

但现在的问题是，在我们的例子中，它跳转到了函数的开头而不是 0x123。

Answer 1

x86 上的条件跳转指令都采用相对位移，而不是绝对地址。它们可以跳转到代码中的另一个标签，因为汇编器可以计算跳转指令和目标之间的位移，但是您不能使用它们跳转到绝对地址，除非您在汇编时知道您所在的地址代码将被加载。

x86 上的近似绝对跳转是间接的：您需要将地址保存在寄存器或内存中。而且这种跳转只能以无条件的形式使用，因此您必须使用有条件的跳转才能到达它们。

你可以的

my_hook:
    push rbp        
    mov rbp, rsp

    mov dword [rcx + 0x18], 99   

    test rcx, rcx
    je jump_elsewhere
    lock dec dword [rcx + 0x08]
    jne jump_elsewhere
    mov rcx, [rsp + 0x30]

    leave   
    ret

jump_elsewhere:
    mov rax, 0x7FF7847902EE
    jmp rax

如果你不能腾出一个寄存器，你可以这样做

jump_elsewhere:
    jmp [rel elsewhere_addr]
elsewhere_addr: 
    dq 0x7FF7847902EE

但这是更多字节的代码。

如果您确实知道将加载代码的地址，并且该地址在目标地址的 2 GB 范围内，则可以使用 ORG 指令将其告知汇编程序。所以如果my_hook 的地址是0x7ff7DEADBEEF，你可以这样做

    org 0x7ff7DEADBEEF
my_hook:
    ; ...
    je 0x7FF7847902EE

汇编器将计算正确的 32 位位移。

顺便说一句，test rcx, rcx 并没有真正的意义：如果rcx 为零，那么前面的指令mov dword [rcx + 0x18], 99 就会出错，因为在任何体面的操作系统上，零页都将被取消映射。也许您希望这个测试和条件跳转在mov 之前进行。除非这是您正在修补的某种奇怪的裸机代码？