连接到 Oracle DB 时出现 External: SIGSEGV 错误

Question

我会说我如何在 lazarus 上重现这个问题。 我有一个表单和一个使用 zeos 的数据模块来建立与本地 oracle 数据库的连接。 当我将一些代码与数据库对话时出现的问题。 这是一个例子：

OracleMng.ZQuery1.SQL.Clear;      

这正是出错的那一行。 以下是表格的完整代码：

 unit form1;

    {$mode objfpc}{$H+}
    
    interface
    
    uses
      Classes, SysUtils, Forms, Controls, Graphics, Dialogs, DBGrids, StdCtrls,
      datamodule2;
    
    type
    
      { TLogin }
    
      TLogin = class(TForm)
        Button1: TButton;
        DBGrid1: TDBGrid;
        procedure Button1Click(Sender: TObject);
      private
    
      public
    
      end;
    
    var
      Login: TLogin;
    
    implementation
    
    {$R *.lfm}
    
    { TLogin }
    
    procedure TLogin.Button1Click(Sender: TObject);
    begin
    
      OracleMng.ZQuery1.SQL.Clear;
    
    end;
    
    end.

这是数据模块的代码：

unit datamodule2;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, DB, ZConnection, ZDataset, ZSqlMonitor;

type

  { TOracleMng }

  TOracleMng = class(TDataModule)
    DataSource1: TDataSource;
    ZConnection1: TZConnection;
    ZQuery1: TZQuery;
  private

  public

  end;

var
  OracleMng: TOracleMng;

implementation

{$R *.lfm}

{ TOracleMng }



end.

我在努力

    if (OracleMng <>  Nil) and (OracleMng.Zquery1 <> Nil) then OracleMng.ZQuery1.SQL.add('select * from help');
  if (OracleMng <>  Nil) and (OracleMng.Zquery1 <> Nil) then OracleMng.ZQuery1.ExecSQL;
   dbgrid1.refresh; 

我没有更多错误，但 DBGrid1 未填充。

这是我的项目 lpr 文件：

program project1;

{$mode objfpc}{$H+}

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  Interfaces, // this includes the LCL widgetset
  Forms, zcomponent, datamodule2, form1
  { you can add units after this };

{$R *.res}

begin
  RequireDerivedFormResource:=True;
  Application.Scaled:=True;
  Application.Initialize;
  Application.CreateForm(TLogin, Login);
  Application.Run;
end.        

Answer 1

我在评论中建议的更改，即

if (OracleMng <>  Nil) and (OracleMng.Zquery1 <> Nil) then
  OracleMng.ZQuery1.SQL.Clear

显然阻止了您收到 SIGSEGV 错误，这表明您的 DataModule 和 表单的创建顺序错误，即表单优先。去看看这个 项目 |在 IDE 中查看源代码。如果你看到类似的东西

program MyProgram;

[...]

begin
  Application.Initialize;
  Application.MainFormOnTaskbar := True;
  Application.CreateForm(TForm1, Form1);
  Application.CreateForm(TDataModule1, DataModule1);
  Application.Run;
end.

它们的顺序错误，因此交换两条 CreateForm 行

  Application.CreateForm(TDataModule1, DataModule1);
  Application.CreateForm(TForm1, Form1);

有了这个改变，你应该不再需要

if (OracleMng <>  Nil) and (OracleMng.Zquery1 <> Nil) then`

接下来的事情：你似乎对何时使用感到困惑

ZQuery1.ExecSQL

和

ZQuery1.Open

Open 用于当您使用的 SQL 语句生成结果集时，即 可以在 TDBGrid 中查看的记录集合。最常用的方法 是使用 SELECT 语句，如

ZQuery1.SQL.Text := 'select * from MyTable';
ZQuery1.Open;

ExecQuery 用于您的 SQL 语句对数据库执行某些操作的地方 这不涉及选择记录。最常见的需要 ExecSQL 的 SQL 语句是

UPDATE
INSERT
DELETE

虽然还有其他的，例如在 SQL Server 上执行存储过程的语句 （注意有些存储过程返回结果集，所以需要Open，而不是ExecSQL）。

请注意，ExecSQL 将清除数据集中 (ZQuery1) 中的所有记录，因此在 您需要使用合适的 SQL 语句再次打开

var
  S : String;
begin
  S := 'update MyTable set number = number +1 where id = 5';
  ZQuery.SQL.Text := S;
  ZQuery1.ExecSQL;    // no records shown in DBGrid1 from here

  S := 'select * from MyTable';
  ZQuery.SQL.Text := S;
  ZQuery1.Open;    // records shown in DBGrid1 again
end;

请注意我这样做

  S := 'select * from MyTable';
  ZQuery.SQL.Text := S;

而不是

  ZQuery1.SQL.Clear;
  ZQuery1.SQL.Add('select * from myTable');

这样做的原因是在调试器中查看整个 SQL 语句要容易得多 检查变量 S 比检查 ZQuery1.SQL.Text 属性更容易 查看任何语法错误。

您应该始终Close 一个数据集，一旦您完成了对它的使用Opened，因为它可以确保磁盘上的数据是最新的。如果最后一个 SQL 操作是 ExecSQL，则不需要关闭数据集。

如果按照我的方式设置查询的 Text 属性，使用 ZQuery1.SQL.Text，则不需要使用 Clear。无论如何，它只相当于做ZQuery1.SQL.Text := ''，它不会影响数据集的状态——它只会在你调用ExecSQL或Open时做任何事情。