为什么Scheme允许在闭包中突变到封闭环境？

Question

以下方案代码

(let ((x 1))
   (define (f y) (+ x y))
   (set! x 2)
   (f 3) )

计算结果为 5 而不是 4。令人惊讶的是，Scheme 促进了静态作用域。允许后续突变影响闭包中封闭环境中的绑定似乎恢复到有点动态范围。允许的任何具体原因？

编辑：

我意识到上面的代码不太明显地揭示了我所关心的问题。我在下面放了另一个代码片段：

(define x 1)

(define (f y) (+ x y))

(set! x 2)

(f 3)  ; evaluates to 5 instead of 4

Answer 1

您在这里混淆了两个想法：作用域和通过内存进行间接寻址。词法作用域保证你对x的引用总是指向x在let绑定中的绑定。

这在您的示例中没有违反。从概念上讲，let 绑定实际上是在内存中创建一个新位置（包含1），该位置 是绑定到x 的值。当该位置被取消引用时，程序会在该内存位置查找当前值。当您使用set! 时，它会设置内存中的值。只有有权访问绑定到x 的位置（通过词法范围）的各方才能访问或改变内存中的内容。

相比之下，动态范围允许任何代码更改您在f 中引用的值，无论您是否授予对绑定到x 的位置的访问权限。例如，

(define f
  (let ([x 1])
    (define (f y) (+ x y))
    (set! x 2)
    f))

(let ([x 3]) (f 3))

将在具有动态范围的虚构方案中返回 6。

Answer 2

允许这种突变非常好。它允许您定义具有内部状态的对象，只能通过预先安排的方式访问：

(define (adder n)
  (let ((x n))    
    (lambda (y)
      (cond ((pair? y) (set! x (car y)))
            (else (+ x y))))))

(define f (adder 1))
(f 5)                 ; 6
(f (list 10))
(f 5)                 ; 15

没有办法改变x，除非通过f 函数及其已建立的协议——正是因为Scheme 中的词法 作用域。

x 变量指的是内部环境框架中属于 let 的内存单元其中定义了内部lambda - 因此返回lambda 和它的定义环境，也称为“闭包”。

如果你不提供改变这个内部变量的协议，没有什么可以改变它，因为它是 internal 并且我们早就离开了定义范围：

(set! x 5) ; WRONG: "x", what "x"? it's inaccessible!

---

编辑：您的新代码完全改变了您问题的含义，那里也没有问题。就像我们仍然在那个定义环境中一样，所以内部变量自然仍然可以访问。

比较有问题的是下面

(define x 1)
(define (f y) (+ x y))
(define x 4)
(f 5) ;?? it's 9.

我希望第二个定义不会干扰第一个，但R5RS 说define 就像顶级的set!。

闭包将其定义环境与它们打包在一起。 始终可以访问顶级环境。

f 引用的变量x 位于顶级环境中，因此可以从同一范围内的任何代码访问。也就是说，任意代码。

Answer 3

不，它不是动态范围。请注意，这里的define 是一个内部定义，只能由let 中的代码访问。具体来说，f 没有在模块级别定义。所以什么都没有泄露出去。

内部定义在内部实现为letrec (R5RS) 或letrec* (R6RS)。因此，它被视为相同（如果使用 R6RS 语义）：

(let ((x 1))
  (letrec* ((f (lambda (y) (+ x y))))
    (set! x 2)
    (f 3)))

Answer 4

我的答案很明显，但我认为其他人没有触及它，所以让我说吧：是的，这很可怕。您在这里真正观察到的是，突变使您很难推断您的程序将要做什么。纯功能代码——没有突变的代码——在使用相同的输入调用时总是产生相同的结果。具有状态和突变的代码不具有此属性。使用相同的输入调用一个函数两次可能会产生不同的结果。