Init.m 注意事项和良好做法

Question

由于我从未找到（或者可能我从未找到足够多的内容）关于如何管理 init.m 文件的好文章，因此我最终开发了自己的“标准”，但我想知道我做得有多糟糕。

例如，我常用的 init.m 存储在 C:\Documents and Settings\All Users\Application Data\Mathematica\Kernel\init.m (Windows) 中，我使用文本编辑器对其进行编辑。

由于我不希望定义进入全局上下文，因此内容类似于：

(** User Mathematica initialization file **)
Begin["MyInitContext`"];

Cl:=Clear["Global`*"];
(* Other definitions in this Context *)

End[]; (* End Context *)
$ContextPath = Prepend[$ContextPath,"MyInitContext`"];

我不从 init.m 加载包，因为我想严格控制我加载的内容，所以我在这里只定义了我日常使用的实用程序功能的快捷方式和一些选项。

那么：有没有提到好的做法？实现这种行为的更好方法？有什么注意事项吗？

Answer 1

首先，我强烈建议不要放置任何重要的init.m，因为这总是会导致几年后您再使用旧的东西时被破坏。将您的自定义设置放在路径上会更好，这样您就可以在每个笔记本的头部快速加载它：这样可以明确说明上下文，您可以轻松更改版本而不会破坏旧内容。

我当前的设置是从Needs["Janus`"] 开始，其中Janus 目录有一个自定义init.m 文件，该文件将目录中的每个文件加载到上下文中。这意味着我可以在每个自己的文件中添加实用程序函数，就像这个 (clear_cache.m)：

ClearCache::usage="ClearCache[f] unsets all numeric-only downvalues of f, \
  see http://stackoverflow.com/questions/5086749"     

Begin["`Private`"];
ClearCache[f_Symbol] := 
  DownValues[f] = DeleteCases[DownValues[f], _?(FreeQ[First[#], Pattern] &)]
End[]

这是文件Janus/init.m。请注意，它会打印出加载的扩展的名称，所有这些都是本着保持上下文明确而没有太多麻烦的精神。

Module[{packageName,packageFileName,fileNames},
  (* $Input is set to Foo.m when evaluating Foo/init.m *)
  If[$Input=="", Print["init.m cannot run interactively"];Abort[]];
  packageName=StringDrop[$Input,-2];
  packageFileName=FindFile[packageName<>"`"];
  If[packageFileName==$Failed, Print["Unable to find package "<>packageName];Abort[]];
  fileNames=Select[
    FileNames["*.m",{DirectoryName@packageFileName},1],
    FileBaseName[#]=!="init"&];
  Print["Loading extensions from "<>DirectoryName@packageFileName<>" to context "<>packageName<>"`:"];
  BeginPackage[packageName<>"`"];
  Do[Print["Loading "<>fn]; Get@fn, {fn,fileNames}];
  EndPackage[]]

Answer 2

我的Kernel/init.m 看起来像这样：

AppendTo[$Path, Environment["MMA_LIB"]]
Needs["WRUtil`"]

WRUtil 包含我所有的小实用程序，并执行考虑到平台和 Mathematica 版本的其他初始化。 MMA_LIB 是一个环境变量，指向一个充满 Mathematica 包的目录。该目录受版本控制，可以由多个 Mathematica 实例共享。我喜欢让init.m 保持简短，以便进入新的 Mathematica 安装就像输入我已经记住的两行代码一样简单——令人惊讶的是，我似乎不得不经常这样做。

Answer 3

我也没有遵循官方的教义，我只能告诉你我是做什么的。

我的Kernel/init.m 本身不包含任何功能。我用它来：

• 设置某些选项：$HistoryLengthSetDirectory 等
• 做一点清理工作（我不喜欢从空白笔记本开始）
• 设置我想要的DeclarePackage 呼叫
• 加载我的自定义函数包