关于 Manipulate 内部动态、同步更新的问题

Question

我正在尝试查看是否可以在 Manipulate 中创建自己的模拟循环，因为我对 Trigger 控件或使用 Tasks 都不满意（对于我想做的事情都有问题和限制）。

所以，我想看看我是否可以制作自己的控制循环，这样我可以更好地控制事物，通过点击“运行”按钮，模拟循环将开始，直到点击“停止”按钮.

一个基本问题是 Manipulate 在 5 秒后超时，即使我使用的是 SynchronousUpdating -> False。即，当我单击“运行”按钮时，我开始一个循环（其中当然包含一些 Pause[]），然后将更新循环中的某些内容。这工作正常，但 5 秒后，循环自行停止，因为 Manipulate 决定超时。

我可能在这里误解了一些基本的东西。我在下面展示一个简单的例子：

Manipulate[
Dynamic[Refresh[Text@x,TrackedSymbols->{x}]],

{{x,0},ControlType->None},
{{running,True},ControlType->None},

Button[Text["play"],
  {
   running=True,
   While[running,
     x+=1;
     FinishDynamic[];
     Pause[0.1]
   ]
  }],

Button[Text["stop"],
    running=False
  ],

TrackedSymbols->{None},
SynchronousUpdating->False,
SynchronousInitialization->False
]

当运行上面的时候，它总是在 count 58 左右停止，大约是 5 秒，Manipulate 的超时值

在 Manipulate 之外，它可以正常工作：

x = 0;
Dynamic[Refresh[x, UpdateInterval -> 0.001]]

Do[
 (
  x += 1;
  FinishDynamic[];
  Print[x];
  Pause[0.01]
  ), {i, 0, 200}
 ]

我可以将上面的计数设置为任意大小，没问题。

所以，它似乎是 Manipulate 的一个配置选项，但我现在无法找到我需要使用哪个选项才能使其工作。

谢谢

更新

使用 Simon 下面给出的 Method->“Queued”，现在循环可以工作了。但是这种方法存在问题：当 Button 运行时，我无法使用 Mathematica，即使循环中有很大的暂停，因为它阻塞了整个前端。它的行为就像按钮一直被按下一样。所以，这个想法是没有问题的。好吧，这是可以尝试的。

顺便说一句，现在是提及这一点的好时机，我发现使用“代码”类型的单元而不是默认的“输入”会导致内核中的许多崩溃。刚刚尝试了单元格类型“代码”，点击几下按钮后，内核崩溃了：

所以我不再使用“代码”类型的单元格。

回到绘图板。

更新 2：2011 年 8 月 29 日下午 6 点

在 Windows 7、SP1、intel pc 上使用 Mathematica 8.0.1，这是使用“代码”单元格时崩溃的代码

Manipulate[
Dynamic[Refresh[Text@x,TrackedSymbols->{x},UpdateInterval->0.005]],

{{x,0},ControlType->None},
{{running,True},ControlType->None},

Button[Text["play"],
  {
   running=True,
   While[running,
     x+=1;
     FinishDynamic[];
   ]
  },Method->"Queued"],

Button[Text["stop"],
    running=False
  ],

TrackedSymbols->{None},
SynchronousUpdating->False,
SynchronousInitialization->False
]

可能有人可以尝试上述方法吗？必须点击启动/停止几次才能让它崩溃。

我可以重现这个。

2011 年 9 月 2 日更新

关于新答案：在我的电脑 Mathematica 8.0.1 上，看起来 Simon 版本（下面的第二个）似乎更快。我两个同时启动，Simon版本好像跑得更快（计数器跑得更快）。

屏幕截图：

Answer 1

我认为实际上是 Button 超时，而不是 Manipulate。

引用Button docs 的Options > Method 部分，

默认情况下，按钮功能在抢先链接上进行评估，该链接 5 秒后超时：

为按钮设置选项Method -> "Queued"，一切正常。

Answer 2

如果你让Manipulate控制“循环”，你可能会得到更好的结果：

Manipulate[
  If[running, x++, x]
, {{x, 0}, ControlType -> None}
, {{running, True}, ControlType -> None}
, Button["play", running = True]
, Button["stop", running = False]
]

我认为Manipulate 在这里被用来支持实际应用程序中的进一步控制。如果没有，那么DynamicModule 就足够了。

DynamicModule[{x = 0, running = True}
, Column[
    { Button["play", running = True]
    , Button["stop", running = False]
    , Dynamic[If[running, x++, x]]
    }
  ]
]

以下示例使用此技术为移动的磁盘设置动画：

DynamicModule[{t = 0, running = True}
, Column[
    { Button["play", running = True]
    , Button["stop", running = False]
    , Dynamic[
        If[running, t++, t] /.
          t_ :> Graphics[Disk[{Cos[t/10], Sin[t/10]}]
                       , PlotRange -> {{-3,3},{-3,3}}
                       , Axes -> True
                       ]
      ]
    }
  ]
]