在 systemverilog 中随机化对象队列答案

【问题标题】：Randomize a queue of objects in systemverilog在 systemverilog 中随机化对象队列
【发布时间】：2018-03-07 11:19:12
【问题描述】：

我已经看到用于随机化整数值队列的技术，但我在处理对象队列时遇到了困难。示例代码：

class int_queue_class;
  rand int x[$];

  function void print;
    $display($sformatf("Size: %0d", x.size()));
    foreach(x[i])
      $display($sformatf("x[%0d] = %0d", i, x[i]));
  endfunction : print

endclass : int_queue_class


class obj;
  rand int value;
endclass : obj

class obj_queue_class;
  rand obj x[$];

  function void print;
    $display($sformatf("Size: %0d", x.size()));
    foreach(x[i])
      $display($sformatf("x[%0d] = %0d", i, x[i].value));
  endfunction : print

endclass : obj_queue_class


program top();
  initial
  begin
    int_queue_class iqc;
    obj_queue_class oqc;
    iqc = new();
    iqc.randomize() with {x.size() == 5; x[2] == 5;};
    iqc.print();
    oqc = new();
    oqc.randomize() with {x.size() == 5; x[2].value == 5;};
    oqc.print();
  end
endprogram : top

对于对象，似乎不能使用相同的方法。有没有办法使这样的队列随机化，同时保持同时约束队列大小和单个元素字段的能力？我提出的使用前/后随机化方法的想法都至少放弃了这两个选项中的一个。

【问题讨论】：

您应该直接在问题中发布代码。自从他们开始要求用户登录后，EDAPlayground 就不再那么有用了。
感谢您指出这一点，我已将 EDA PlayGround 链接替换为实际使用的代码。
队列的随机化被实现为动态数组。

标签： class random queue system-verilog

【解决方案1】：

随机化不会创建新对象。当您随机化队列的大小时，它将创建包含默认值的新条目，对于类类型，默认值为 null。

您唯一能做的就是在队列中预先分配对象，以便有一些空闲。您将无法随机化比最初创建的对象更多的对象，因此这会限制队列大小的值：

class obj_queue_class;
  rand obj x[$];
  local const max_size;

  constraint legal_size {
    x.size() <= max_size;
  }

  function void pre_randomize();
    x = new[max_size];
    foreach (x[i])
      x[i] = new();
  endfunction

  function void print();
    $display($sformatf("Size: %0d", x.size()));
    foreach(x[i])
      $display($sformatf("x[%0d] = %0d", i, x[i].value));
  endfunction

endclass

我已将 max_size 设为局部常量值，但它可以是您可以从外部设置的值、包参数等。

在pre_randomize() 中实例化max_size 对象。由于x.size() 始终小于或等于max_size，因此随机化的任何值都将导致包含对象实例且不为空的队列。当队列缩小时，其余的对象将被丢弃。

【讨论】：