如何让 Fortran 识别我的函数返回类型？ [复制]

Question

我正在学习 Fortran，我必须编写一个函数来计算一个数字的阶乘。这是我的代码：

program functions
    implicit none

    integer :: fact

    fact = factorial(5)
    print *, fact
    
end program functions

recursive function factorial(n) result(factResult)
    implicit none

    integer :: n
    integer :: factResult

    if (n == 0 .or. n == 1) then
        factResult = 1
    else 
        factResult = n * factorial(n - 1)
    end if

end function factorial

我认为我的代码应该可以工作，但我无法编译，我在调用 factorial(5) 时收到此消息：

Return type mismatch of function 'factorial' at (1)

(UNKNOWN/INTEGER(4)) Function 'factorial' at (1) has no IMPLICIT type

我不知道出了什么问题，似乎没有检测到我的返回类型。在不使用接口或模块的情况下，我该怎么做才能使我的功能正常工作？因为我处于初级水平。

我正在使用 Visual Studio Code，并且正在使用 gfortran 进行编译。

Answer 1

您的主程序无法识别factorial() 函数。请注意，即使您的函数与主程序在同一个文件中，但这并不意味着主程序可以自动找到该函数。解决您的问题的一个简单方法是扩展您的主程序以包含该函数，

program functions
    implicit none

    integer :: fact

    fact = factorial(5)
    print *, fact

contains
    
    recursive function factorial(n) result(factResult)
        implicit none
    
        integer :: n
        integer :: factResult
    
        if (n == 0 .or. n == 1) then
            factResult = 1
        else 
            factResult = n * factorial(n - 1)
        end if
    
    end function factorial

end program functions

在tutorialspoint online Fortran compiler 上测试它，你的程序打印出来了，

120

解决问题的更好更通用的方法是将您的函数放入一个模块中，然后将 use 模块放入您的主程序中，或任何其他可能需要的地方。

module factorial_mod
    
    implicit none

contains
    
    recursive function factorial(n) result(factResult)
        implicit none
    
        integer :: n
        integer :: factResult
    
        if (n == 0 .or. n == 1) then
            factResult = 1
        else 
            factResult = n * factorial(n - 1)
        end if
    
    end function factorial

end module factorial_mod

program functions

    use factorial_mod, only: factorial
    implicit none

    integer :: fact

    fact = factorial(5)
    print *, fact
    
end program functions

另外，请记住，factorial 结果可能会增长得非常快，很容易导致整数溢出。您最好使用 64 位整数来返回结果（在阶乘函数中使用use iso_fortran_env, only: int64），或者甚至更好地返回结果的自然对数（作为实数类型）而不是整数值。