如何访问 Assembly 中的每个单词？

Question

给定：

.data
arr: .word 2,5,1,3,4
len: .word 5
sum: .word 0

如何访问“arr”中的每个单词，例如 2、3 和 4？

最终，我想做的是找到“arr”中所有值的总和，但我在遍历“arr”时遇到了困难。

感谢您的宝贵时间！

附加信息：

1. 我正在使用 eduMIPS64

Answer 1

首先将数组的地址加载到寄存器中，然后您可以访问具有恒定偏移量的项目。 （您的汇编器可能支持诸如lw $t0, arr+12 之类的结构作为方便的简写。请参阅您的手册。）对于迭代，要么增加地址寄存器，要么添加另一个包含偏移量的寄存器。请务必考虑项目大小。以下示例适用于 32 位 mips，根据需要调整 64 位：

.data
arr: .word 2,5,1,3,4
len: .word 5
sum: .word 0

.text
.globl main
main:
    la $t0, arr
    lw $t1, 12($t0)     # load arr[3] using byte offset
    li $t1, 3           # index
    sll $t1, $t1, 2     # multiply by item size
    addu $t1, $t1, $t0  # add base address
    lw $t1, ($t1)       # load arr[3]

# iteration type 1
# for(i=len, ptr=arr; i != 0; i -= 1, ptr += 1)
# ... use *ptr ...
    la $t0, arr
    lw $t1, len         # load length
loop1:
    lw $t2, ($t0)       # load item
    # process item here
    addi $t0, $t0, 4    # add item size to pointer
    addi $t1, $t1, -1   # decrement counter
    bne $t1, $0, loop1  # if counter != 0, repeat

# iteration type 2
# for(i=0, i != len; i += 1)
# ... use arr[i] ...
    la $t0, arr
    lw $t1, len         # load length
    li $t2, 0           # index
loop2:
    sll $t3, $t2, 2     # multiply by item size
    addu $t3, $t3, $t0  # add base address
    lw $t3, ($t3)       # load item
    # process item here
    addi $t2, $t2, 1    # increment index
    bne $t2, $t1, loop2 # if index != len, repeat

（注意这些示例循环不处理零长度数组，必要时添加检查）