kdb/q：如何连接字符串列表中的相邻元素，其间有空格？

Question

提前感谢您的帮助！ （我来自 C++ 和 Python 背景，在 kdb 中不使用 while 循环对我来说很难）

在 kdb/q 中，我有一个字符串列表，我们称之为“test”，它看起来像这样。此列表中有 7 个条目，每个条目都是一个字符串。索引 2 和 4 处的条目（字符串）为空。

test
"col_1:abc col_2:xyz"
"col_3:ijk"
""
"col_1:efg col_2:lmn"
""
"col_1:bah"
"col_3:muy"

我想将相邻的条目连接在一起，如下所示。相邻的条目用空格连接在一起，空的条目消失了

"col_1:abc col_2:xyz col_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bah col_3:muy"

这是我迄今为止最好的尝试。我确信我过于复杂了，一定有更好的方法。

show {$[x~"";"|";x]}each test
"col_1:abc col_2:xyz"
"col_3:ijk"
"|"
"col_1:efg col_2:lmn"
"|"
"col_1:bah"
"col_3:muy"

show raze {$[x~"";"|";x]}each test
"col_1:abc col_2:xyzcol_3:ijk|col_1:efg col_2:lmn|col_1:bahcol_3:muy"

show "|" vs raze {$[x~"";"|";x]} each test
"col_1:abc col_2:xyzcol_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bahcol_3:muy"

我很接近，但我没有在新列表的索引 0 处将“col_2:xyz”与“col_3:ijk”分隔开的所需空格，并且我没有分隔“col_1:bah”的空格来自新列表索引 2 处的“col_3:muy”。如何克服这个问题？非常感谢您的指点/提示，谢谢

Answer 1

上述没有连续空字符串的情况的快速解决方案

q)"  "vs" "sv test
"col_1:abc col_2:xyz col_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bah col_3:muy"

Answer 2

如果从文件中读取字符串列表，另一种选择是使用read1 将文件读取为字节，而不是使用read0 读取为字符串。例如

q)"  " vs {@[x;where x=0x0a;:;0x20]} read1`:test.txt
"col_1:abc col_2:xyz col_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bah col_3:muy "

在这里，我们将换行符 (0x0a) 替换为空格 (0x20)，然后在任何双空格上进行拆分（即是否有空行）。

需要注意的是，如果文件以新行结尾，则最后一个字符串有一个尾随空格（取决于您如何使用新的字符串列表，这可能无关紧要，但如果确实如此，可能会删除最后一个字符，或使用trim 删除等）

Answer 3

你自己的方法会这样工作：

q)trim"|"vs" "sv{$[x~"";1#"|";x]}each test
"col_1:abc col_2:xyz col_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bah col_3:muy"

这是一个使用cut的替代方法

q){ltrim" "sv'cut[0,where""~/:x;x]}[test]
"col_1:abc col_2:xyz col_3:ijk"
"col_1:efg col_2:lmn"
"col_1:bah col_3:muy"