我可以引用带有一些参数的命名子例程吗答案

【问题标题】：Can I reference a named subroutine with some arguments我可以引用带有一些参数的命名子例程吗
【发布时间】：2020-04-15 18:07:57
【问题描述】：

我有一个带有多个参数的子例程，并希望使用其中一个参数集来引用它，这样引用就少了一个参数。最佳情况是

my $subref = \&routine($arg1);
...
my $result = $subref->($arg2,$arg3);

在perlref 中有一个这样的匿名子例程的示例，但是我无法通过命名的子例程获得等效项。

下面是我的意思的完整示例。虽然 $func （引用匿名子）和 $func2 （引用命名子，但没有参数）工作。 $func3 给出错误“不是代码引用[...]”。

我错过了什么还是这实际上是不可能的？

use strict;
use warnings;

sub args{
    my $arg1 = (shift or "none");
    my $arg2 = (shift or "none");
    my $arg3 = (shift or "none");
    my (undef, undef, undef, $function) = caller(0);
    return "me: $function\narg1 = $arg1\narg2 = $arg2\narg3 = $arg3\n";
}

sub just_a_ref {
    return \&args;
}

sub new_arg_anon {
    my $arg = shift;
    return sub{
        my $arg1 = $arg;
        my $arg2 = (shift or "none");
        my $arg3 = (shift or "none");
        my (undef, undef, undef, $function) = caller(0);
        return "me: $function\narg1 = $arg1\narg2 = $arg2\narg3 = $arg3\n";
    }
}

sub new_arg {
    my $arg = shift;
    return \&args($arg);
}


my $func = new_arg_anon("one");
print $func->("two","three");     #works fine
my $func2 = just_a_ref();
print $func2->("un", "deux", "trois");  #works fine
my $func3 = new_arg("eins");
print $func3->("zwei", "drei");   #Not a CODE reference

【问题讨论】：

标签： perl reference arguments subroutine

【解决方案1】：

你必须创建一个新的匿名函数来做这件事。使用一个参数集调用目标函数并将其余参数传递给它。在您的示例中， new_arg 函数应该是：

sub new_arg {
    my $arg = shift;
    return sub {args($arg, @_)};
}

【讨论】：

谢谢。也比我担心的要简单得多。

【解决方案2】：

\&args($arg)是\( args($arg) )，即对函数调用args($arg)的返回值的引用，而不是对使用参数$arg调用的函数args的引用。

print $func3;   # SCALAR(0x8000a1a50)

要引用执行args 子例程且$arg 作为第一个参数的函数，请使用

sub new_arg {
    my $arg = shift;
    return sub { args($arg,@_) };
}

（看看那个，就像 Georg Mavridis 的回答一样）

【讨论】：

"就像..." -- 更糟糕的是，甚至附带解释！