使用 Storable 存储哈希并在另一个脚本中使用它

Question

我将哈希存储在这样的脚本中（部分代码省略）：

use strict;
use warnings;

use utf8;

use Storable qw(nstore_fd);

open( my $fh, ">",  'hash.hash');
my $hash_ref = \%hash;
nstore_fd($hash_ref, $fh);
close $fh;

这会创建一个文件hash.hash。然后，在另一个文件中，我尝试“导入”散列并读取其要使用的值（例如，循环散列、读取值、检查存在......）。

我尝试了一些简单的方法，即读取哈希、取消引用并读取其键，然后将其打印出来。但是我收到错误Not a HASH reference at CreateSql.pl line 12. 这是一个标量。但我不明白为什么。模块的The documentation 声明返回一个引用。

要检索存储到磁盘的数据，请使用带有文件名的retrieve。这 存储在该文件中的对象会为您重新创建到内存中，并且 返回对根对象的引用。

那么我做错了什么，如何访问存储的哈希？

use strict;
use warnings;

use utf8;

use Data::Dumper;
use Storable qw(retrieve);

my ($hash_path) = @ARGV;

my $hash_ref = retrieve($hash_path);

my @keys = keys % { $hash_ref }; # throws error
print Dumper(\@keys);

Answer 1

你真的必须展示给你所描述的问题的代码，否则很难帮助你。您问题中的代码无法编译。如果您想在发布程序之前对其进行更改，再次测试以确保它至少可以编译，并显示您报告的问题

主要问题是您将二进制数据写入以文本形式打开的文件。如果您将open( my $fh, ">", 'hash.hash') 更改为open( my $fh, ">:raw", 'hash.hash')，那么一切正常

您自己的代码变体可以正确存储和检索一些示例数据

use strict;
use warnings 'all';

use Storable qw/ nstore_fd retrieve /;

use constant STORAGE => 'hash.hash';

my %hash = ( a => 'b', c => 'd' );

{
    open my $fh, '>:raw',  STORAGE or die $!;
    nstore_fd \%hash, $fh;
}

my $hash_ref = retrieve STORAGE;

use Data::Dump;

dd $hash_ref;

my @keys = keys % { $hash_ref }; # throws error
dd \@keys;

输出

{ a => "b", c => "d" }
["a", "c"]

但是，您做出了一些奇怪的选择。无需使用nstore 函数以“网络顺序”存储数据，如果您让模块自己打开文件，您可以完全避免这个问题

这是一个仅使用store 和retrieve 的变体。输出与上面的代码相同

use strict;
use warnings 'all';

use Storable qw/ store retrieve /;

use constant STORAGE => 'hash.hash';

my %hash = ( a => 'b', c => 'd' );

store \%hash, STORAGE;

my $hash_ref = retrieve STORAGE;

use Data::Dump;

dd $hash_ref;

my @keys = keys % { $hash_ref }; # throws error
dd \@keys;