如何在我的活动工作表上动态创建一个按钮？

Question

所以我在我的工作簿中创建了一个主菜单，如果用户单击一个按钮，则会创建一个新工作表并打开以供用户查看一些数据。

现在，我想动态地（通过 VBA 代码）在当前活动的工作表上创建一个按钮，其中包含让用户关闭工作表的数据（本质上是删除 ActiveSheet 并返回到主菜单)

我尝试查看 VBA 帮助以获取有关按钮控件的信息，但我只能找到有关 CommandButton 的信息（我相信它只能在用户窗体中使用）。

• 我的这种看法有错吗？CommandButton 也可以在用户窗体之外使用吗？
• 或者是否有我找不到的 Button 对象？

我搜索了这个主题，只找到了这篇文章，但它不起作用。如果有帮助，我正在使用 Excel 2010。 How to add a button programmatically in VBA next to some sheet cell data?

Answer 1

解决此问题的一种方法是使用模板。使用所述按钮创建工作表。在工作表模块中你使用这个：

Private Sub CommandButton1_Click()
    Me.Delete
    ThisWorkbook.Worksheets("MainMenu").Activate
End Sub

在创建工作表时，您会像这样使用此模板：

Public Sub CopySheet()

    ThisWorkbook.Worksheets("Template").Copy After:=Sheets(Sheets.Count)

    With ActiveSheet
        .Name = "Your Name"
    End With

    'Fill with data etc....

End Sub

复制的模板现在有您的删除按钮。还有其他方法可以解决，但这可能是最简单的。

P.s.：要向工作表添加按钮，请在开发人员选项卡中向工作表“添加”表单或 active-X 控件。使用哪一个与模板无关。

Answer 2

这是另一种方式...

Sub CreateSheetAddButton()

    ' Set the worksheet to a new sheet
    Dim ws As Worksheet
    With ThisWorkbook
        Set ws = .Sheets.Add(After:=.Sheets(.Sheets.Count))
    End With

    Dim btn As Button
    ' Add a button and assign an onaction macro
    With ws
        .Name = "YourName"
        Set btn = .Buttons.Add(71.25, 26.25, 107.25, 63.75)
    End With

    With btn
        .OnAction = "DeleteWS"
        .Caption = "Delete Current Sheet"
        .Name = "btnDel"
    End With

    ' Clean up
    Set ws = Nothing
    Set btn = Nothing

End Sub

Sub DeleteWS()

    Dim ws As Worksheet, wsMain As Worksheet
    Set ws = ThisWorkbook.ActiveSheet
    Set wsMain = ThisWorkbook.Worksheets("Main")

    With ws
        Application.DisplayAlerts = False
        ws.Delete
        wsMain.Activate
        Application.DisplayAlerts = True
    End With

    ' Clean up
    Set ws = Nothing
    Set wsMain = Nothing

End Sub