Java字节数组转Delphi字节数组

Question

我正在开发 Android 蓝牙打印。打印机是标准的 POS 热敏打印机。

这是我将数据发送到打印机的方式（这部分正在工作）：

var
    Adapter: JBluetoothAdapter; 
    remoteDevice: JBluetoothDevice;
    Sock: JBluetoothSocket;
    ostream: JOutputStream;
begin
    Adapter := TJBluetoothAdapter.JavaClass.getDefaultAdapter;
    remoteDevice := Adapter.getRemoteDevice(stringtojstring(targetMAC));
    Sock := remoteDevice.createRfcommSocketToServiceRecord(uid);
    ostream := Sock.getOutputStream;

    ....    
    function StringToJA(Data: String): TJavaArray<Byte>;
    var
      X: integer;
      len: integer;
    begin
      len := Length(Data);
      Result := TJavaArray<Byte>.Create(len);
      for X := 0 to len do
      begin
        Result.Items[X] := Ord(Data[X]);
      end;
    end;    
    // THIS LINE PRINT TEXT
    ostream.write(StringToJA(txt));

现在我想加载不同的字符编码，这是 JAVA 中的代码：

 int a=23;
 String codeL="iso8859-2";
 String txt="SOME TEXT...ščž";
 byte data[] = txt.getBytes(codeL);
 byte sendText[]=new byte[3];
 sendText[0]=0x1B;
 sendText[1]=0x74;
 sendText[2]=(byte)a;
 mobileprint.PRTSendBuffer(sendText, sendText.length);   

如何转换这些行？

• txt.getBytes(codeL);
• sendText[2]=(byte)a;

Delphi XE5 代码：

 ...
  A : Integer;
  txt, codeL: string;
  data : TJavaArray<Byte>;
  sendText : TJavaArray<Byte>;
begin
  A := 23;
  codeL := 'iso8859-2';
  txt := 'SOME TEXT...ščž';
  data := ??? txt.getBytes(codeL); ???
  sendText := TJavaArray<Byte>.Create(3);
  sendText.Items[0] := $1B;
  sendText.Items[1] := $74;
  sendText.Items[2] := ???Byte(A)???;

  ostream.write(sendText);
  ostream.write(data);

这是来自 Exlipse 的 JAVA 表达式值：

Answer 1

对于 X := 0 to len do

那应该使用len-1，否则你会超出数组和字符串的范围。

在将字符串复制到字节数组时，您也没有考虑 Unicode，因此如果 string 包含任何需要使用 UTF-16 代理的非 ASCII 字符，您可能会遇到问题。您应该先使用SysUtils.TEncoding 类将string 转换为Delphi 字节数组，然后将其复制到Java 字节数组中，例如：

function StringToJA(Data: String): TJavaArray<Byte>;
var
  Arr: TBytes;
  len, X: integer;
begin
  Arr := TEncoding.Default.GetBytes(Data); // or any other TEncoding you need
  len := Length(Arr);
  Result := TJavaArray<Byte>.Create(len);
  for X := 0 to len-1 do
    Result.Items[X] := Arr[X];
end;    

或者，摆脱循环：

function StringToJA(Data: String): TJavaArray<Byte>;
var
  Arr: TBytes;
  len: integer;
begin
  Arr := TEncoding.Default.GetBytes(Data);
  len := Length(Arr);
  Result := TJavaArray<Byte>.Create(len);
  if len > 0 then Move(Arr[0], Result.Data^, len);
end;

如何转换这些行？

txt.getBytes(codeL);
sendText[2]=(byte)a;

同样，通过使用TEncoding 类，例如：

function StringToJA(Data: string; charset: String = ''): TJavaArray<Byte>;
var
  Encoding: TEncoding;
  Arr: TBytes;
  len: integer;
begin
  if charset <> '' then 
    Encoding := TEncoding.GetEncoding(charset)
 else
    Encoding := TEncoding.Default;
  Arr := Encoding.GetBytes(Data);
  len := Length(Arr);
  Result := TJavaArray<Byte>.Create(len);
  if len > 0 then Move(Arr[0], Result.Data^, len);
end;

var
  txt: string;
  data : TJavaArray<Byte>;
  sendText : TJavaArray<Byte>;
begin
  txt := 'SOME TEXT...ščž';
  data := StringToJA(txt, 'iso8859-2');

  sendText := TJavaArray<Byte>.Create(3);
  sendText.Items[0] := $1B;
  sendText.Items[1] := $74;
  sendText.Items[2] := Byte(23);

  ostream.write(sendText);
  ostream.write(data);