埃菲尔：编译错误`分配源与目标不兼容`

Question

在编译器中设置了完整的 void 检查后，我在以下情况下出现了一个变量未正确设置编译错误，这对我来说是正确的（在我看来）。它说分配的来源与目标不兼容。我在这里想念什么？？？ (DB_SERVICE.load_from_primary_key...)

类 DB_SERVICE

deferred class
    DB_SERVICE [G -> DB_ENTITY create make_from_db_result end]

inherit
    ACTION
        redefine
            start,
            execute
        end

    LOGGABLE
        rename
            make as make_from_loggable
        end

feature -- Creation

    make (a_db_connection: attached DB_CONNECTION)
        require
            valid_db_connection: a_db_connection.is_connected
        do
            make_from_loggable
            db_connection := a_db_connection
            create last_items.make (100)
            create last_column_names.make_empty
        ensure
            db_connection_setted: a_db_connection = db_connection and db_connection.is_connected
        end

feature -- Access

    item: detachable G

    db_connection: DB_CONNECTION

    last_items: HASH_TABLE[like item, INTEGER] -- content of last resultset

    last_column_names: ARRAY[STRING] -- Column names of last resultset

feature -- status_report


    load_from_primary_key (primary_key: INTEGER)
            -- Loads given item into item otherwise item will be Void
        require
            attached db_connection.base_selection
        local
            l_db_result: DB_RESULT
        do
            if attached db_connection.base_selection as bs then
                bs.query ("SELECT * FROM " + ({attached like item}).out + " WHERE " + {attached like item}.Primary_key_db_column_name + "=" + primary_key.out)
                if bs.is_ok then
                    bs.load_result
                    create item.make_from_db_result(last_column_names, bs.cursor)
                else
                    item := Void --HERE is the compiler complaining!
                    logger.write_critical ("Error while retreiving " + ({like item}).out + " from DB")
                end
            else
                item := Void 
                logger.write_error ("base_selection is void")
            end
        end


end -- class

类 COMPANY_SERVICE

class
    COMPANY_SERVICE

inherit
    DB_SERVICE[COMPANY]
        redefine
            make
        end
...

类公司

class
    COMPANY

inherit
    DB_ENTITY
        rename
            primary_key as id,
            set_primary_key as set_id,
            Primary_key_db_column_name as Id_db_column_name
        redefine
            make,
            make_from_db_result,
            out
        end

create
    make,
    make_from_db_result

....

Answer 1

类型声明detachable G 表示如果对应的实际泛型是引用类型，则该类型的变量可以是可分离的。在这种情况下，可以将Void 分配给这样的变量。但是，实际的泛型也可能是扩展类型。扩展类型前缀detachable 无效，类型保持不变，变量不能赋值Void。

作为一个例子，让我们考虑一个更简单的情况，当参数G 没有正式的通用约束时。一个实际的泛型可能是STRING，而变量item 的类型是detachable STRING。在这种情况下，可以将Void 分配给item。

现在，如果实际的泛型是 INTEGER，则变量的类型为 detachable INTEGER，它等价于 INTEGER。将Void 分配给这种类型的变量是没有意义的，并且是语言规则所不允许的。

如果实际的泛型参数是引用类型，变量item 仍然可以设置为Void。为此，可以声明一个相同类型的局部变量，并将其值赋值给item：

local
    default_item: like item
do
    item := default_item