如何在树上使用可遍历

Question

我试图了解如何使用 Traversable 来迭代我的树数据结构。 我有一棵看起来像这样的丑树（实际上是森林）：

data ParseTree a = Leaf a | Node a (ParseTree a) (ParseTree a) | MultiNode a [ParseTree a]
       deriving (Show, Functor, F.Foldable, T.Traversable)

t = Node S 
(Node NP (Leaf DP) (Leaf NP)) 
(MultiNode VP 
[Node VP (Node VP (Leaf VP) (Leaf PP)) (Node NP (Leaf DP) (Leaf NP)),
Node VP (Leaf VP) (Node PP (Leaf PP) (Node NP (Leaf DP) (Leaf NP)))]
)

我想找到多节点，这样我就可以替换构建新树，多节点中的每个项目一个。

对我来说编写这样的函数很容易

findmulti :: ParseTree a -> [ParseTree a]
findmulti (Leaf a) = []
findmulti (Node a left right) = findmulti left ++ findmulti right
findmulti (MultiNode a lst) = [ (MultiNode a lst) ]

但我认为我应该能够使用 traverse 向下查找列表并为我找到项目。 如果我这样做了

traverse print t

我只得到最后的值：

S NP DP NP 副总裁 副总裁 副总裁 副总裁 PP...

但我实际上希望遍历在多节点处停止。如何控制遍历的深度？或者这是不可能的，因为 Traversable 和朋友对容器是不可知的？

最终我想派生出允许我替换多节点的镜头，但现在我只是想了解可遍历的工作原理。我是否使用了正确的工具来完成这项工作？

Answer 1

构建一个Traversal' 访问任何你喜欢的东西是相当容易的，尽管这个功能比Data.Traversable 允许的更通用，因为那个 Traversal 必须只访问并且完全包含元素。

首先，让我们检查traverse的签名

traverse :: (Traversable t, Applicative f) => (a -> f b) -> t a -> f (t b)

我喜欢将第一个参数称为“注入”函数。任何注入Applicative、f 的东西都会被Traversal“访问”。在这种情况下，我们想访问MultiNodes，这样我们就可以专攻这个类型了。

multinodes :: Applicative f => (ParseTree a -> f (ParseTree a)) -> ParseTree a -> (f (ParseTree a))

或者

multinodes :: Traversal' (ParseTree a) (ParseTree a)

现在让我们考虑一下定义。同样，目标是注入每个MultiNode。

-- No multinodes here, so we use `pure` so as to inject nothing at all
multinodes inj l@Leaf{} = pure l

-- Here's a multinode, so we'll visit it with the injection function
multinodes inj m@Multinode{} = inj m

-- And we need to neither reject (thus stopping the traversal)
-- nor inject a branch. Instead, we continue the traversal deeper
multinodes inj (Node a l r) = 
  (\l' r' -> Node a l' r') <$> multinodes inj l
                             <*> multinodes inj r

这是我们的Traversal'。

>>> t ^.. multinodes
[MultiNode VP [Node VP (Node VP (Leaf VP) (Leaf PP)) (Node NP (Leaf DP) (Leaf NP)),Node VP (Leaf VP) (Node PP (Leaf PP) (Node NP (Leaf DP) (Leaf NP)))]]

---

这段代码并没有比为findmulti编写的代码短很多---事实上，它只不过是一个展开的findMulti . traverse，但它立即与其他lens组合器兼容，并演示了一般的方法通过类型提供Applicative，同时针对所需的内部结构。只写一次Traversal' 将成为对MultiNodes 进行几乎任何类型访问的通用工具。