VBA - 通过 Application.Evaluate 的长数组公式

Question

假设我们在单元格 A1 中保存了一些长公式：

=SomeArrayFunction(
IF(SUM(D3:D6)>1,"A-B-C-D-E-F-G-H-I-J-K-L-M-N-O-P-Q-R-S-T-U-V-W-X 01",
"part_one"),
IF(SUM(D3:D6)>1,"A-B-C-D-E-F-G-H-I-J-K-L-M-N-O-P-Q-R-S-T-U-V-W-X 02",
IF(SUM(D3:D6)>1,"A-B-C-D-E-F-G-H-I-J-K-L-M-N-O-P-Q-R-S-T-U-V-W-X 03",
"part_two"))
)

它使用以下 VBA 函数

Public Function SomeArrayFunction(sOne As String, sTwo As String) As Variant
    Dim V() As Variant
    ReDim V(1 To 2, 1 To 1)
    V(1, 1) = sOne
    V(2, 1) = sTwo
    SomeArrayFunction = V
End Function

返回一个 2×1 数组。

---

现在当我调用这个 VBA 函数时

Public Sub EvaluateFormula()
    Dim vOutput As Variant

    vOutput = Application.Evaluate(Selection.Formula)

    If VarType(vOutput) >= vbArray Then
        MsgBox "Array:" & vbCrLf & vOutput(1, 1) & vbCrLf & vOutput(2, 1)
    Else
        MsgBox "Single Value: " & vbCrLf & vOutput
    End If
End Sub

选择单元格 A1 时出现错误，因为 Application.Evaluate 无法处理超过 255 个字符的公式（例如，请参阅 VBA - Error when using Application.Evaluate on Long Formula）。另一方面，如果我写

vOutput = Application.Evaluate(Selection.Address)

相反（如上面链接中所建议的那样），它就可以正常工作。除了不再计算数组这一事实，即调用 MsgBox "Single Value:" 而不是 MsgBox "Array:"。

所以我的问题是：如何使用 VBA 评估长公式（返回数组）？

---

编辑：让我强调一下，当我只选择包含公式的一个单元格（不是一个区域或多个单元格）时，我需要它来工作。而且我没有将它作为数组公式输入（即没有大括号）：

---

Edit2：让我回答一下原因：我目前的工作要求我在电子表格中列出一长串如此庞大的公式。而且由于它们被组织在一个列表中，每个这样的公式只能占用一个单元格。在几乎所有情况下，公式都返回单个值（因此一个单元格足以存储/显示输出）。但是，当计算公式时出现内部错误时，公式会返回错误消息。这些错误消息通常很长，因此以不同大小的数组形式返回（取决于错误消息的长度）。所以我的目标是编写一个 VBA 函数，该函数将首先获取并输出列表中给定选定条目的完整错误消息。

Answer 1

我相信Application.Evaluate 会返回一个与输入地址大小相匹配的结果。我怀疑你的 Selection 是一个单元格，所以它返回一个值。

如果您改为使用 Selection.CurrentArray.Address 调用它，您将得到与正确数组大小相同的答案。

VBA 和 Excel 的图片

用于测试的代码

Public Function Test() As Variant

    Test = Array(1, 2)


End Function

Sub t()

    Dim a As Variant

    a = Application.Evaluate(Selection.CurrentArray.Address)

End Sub

编辑，这里基于 cmets 是一种通过创建新工作表来评估此表外的方法。我正在使用剪切/粘贴方法来确保所有公式都相同。如果单元格不引用剪切的单元格，这可能会更好。但从技术上讲，它不会破坏任何其他单元格，因为我使用的是剪切/粘贴。

在下面的代码中，我在单元格J2 中有一个数组公式，它引用了其他几个单元格。它扩展为 3 行，然后进行 Evaluate 调用。这会返回一个你想要的数组。然后将其缩小为一个单元格并将其移回。

我已经测试了一个简单的例子。我不知道它是否适用于您心目中的应用程序。

Sub EvaluateArrayFormulaOnNewSheet()

    'cut cell with formula
    Dim str_address As String
    Dim rng_start As Range
    Set rng_start = Sheet1.Range("J2")
    str_address = rng_start.Address

    rng_start.Cut

    'create new sheet
    Dim sht As Worksheet
    Set sht = Worksheets.Add

    'paste cell onto sheet
    Dim rng_arr As Range
    Set rng_arr = sht.Range("A1")
    sht.Paste rng_arr

    'expand array formula size.. resize to whatever size is needed
    rng_arr.Resize(3).FormulaArray = rng_arr.FormulaArray

    'get your result
    Dim v_arr As Variant
    v_arr = Application.Evaluate(rng_arr.CurrentArray.Address)

    ''''do something with your result here... it is an array


    'shrink the formula back to one cell
    Dim str_formula As String
    str_formula = rng_arr.FormulaArray

    rng_arr.CurrentArray.ClearContents
    rng_arr.FormulaArray = str_formula

    'cut and paste back to original spot
    rng_arr.Cut

    Sheet1.Paste Sheet1.Range(str_address)

    Application.DisplayAlerts = False
    sht.Delete
    Application.DisplayAlerts = True

End Sub

Answer 2

试试

 vOutput = Application.Evaluate(Selection.CurrentArray.Address)

（假设您有两个单元格，=SomeArrayFunction(...) 作为数组公式输入）

我认为不同之处可能在于评估单个单元格只会得到返回到该单元格的值：整个数组不会在那里返回，只有第一个值。