基于当前月份的批处理文件复制和移动

Question

目前我有一个特定的批处理文件，我需要每个月运行一次。我想把它合并成一个bat文件。如果 2 月 1 日使用 2 月 19 日，则有条件。

如果当前日期是 2019 年 1 月运行

copy "C:\TESTone\*.*" "C:\Jan-19"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\Jan-19\"

如果当前日期是 2019 年 2 月运行

copy "C:\TESTone\*.*" "C:\Feb-19"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\Feb-19\"

如果当前日期是 2019 年 3 月运行

copy "C:\TESTone\*.*" "C:\Mar-19"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\Mar-19\"

Answer 1

这是一个可能的解决方案：

@echo off

setlocal EnableDelayedExpansion

set month[01]=Jan
set month[02]=Feb
set month[03]=Mar
set month[04]=Apr
set month[05]=May
set month[06]=Jun
set month[07]=Jul
set month[08]=Aug
set month[09]=Sep
set month[10]=Oct
set month[11]=Nov
set month[12]=Dec

for /f "tokens=2 delims==" %%A in ('wmic OS Get localdatetime /value') do set "dt=%%A"
set "YY=%dt:~2,2%" & set "MM=%dt:~4,2%"

copy "C:\TESTone\*.*" "C:\!month[%MM%]!-%YY%"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\!month[%MM%]!-%YY%\"
pause

• 启用delayed expansion 在这里会有所帮助，因为我们将在这里需要它，既不在代码块内，也不在一行中设置和使用变量时使用它。这会有所帮助，因为我们想要回显一个其值为另一个变量的名称的变量。
• 设置月份数组。我们使用表单varname[monthnum]。
• 查找date 需要wmic，否则它不会是国际化的。 date 和 time 环境变量由用户定义，通常取决于用户区域设置。
• 现在，设置年份的最后两位数字存储到YY 变量中，月份的两位数字存储在MM 变量中。
• OP 想要的命令是copy "C:\TESTone\*.*" "C:\MMM-YY" 和move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\MMM-YY\"。所以，YY 刚刚准备好，我们有：

copy "C:\TESTone\*.*" "C:\MMM-%YY%"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\MMM-%YY%\"

MMM 是变量month[MM] 的值。所以，在这里使用延迟扩展；用! 和MM 用% 包装数字变量。它将是：

copy "C:\TESTone\*.*" "C:\!month[%MM%]!-YY"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\!month[%MM%]!-YY\"

然后：

copy "C:\TESTone\*.*" "C:\!month[num]!-YY"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\!_num!-YY\"

然后被处理，这实际上是 OP 要求的。

Answer 2

获取区域设置/用户设置独立日期的 wmic 替代方法是 powershell，
可以直接输出想要的格式：

:: Q:\Test\2019\01\07\SO_54070456.cmd
@Echo off
for /f "usebackq" %%A in (`powershell -NoP -C "get-date -f 'MMM-yy'"`) Do set "Month=%%A"
copy "C:\TESTone\*.*" "C:\%Month%"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\%Month%\"

这里唯一回显的结果命令：

> Q:\Test\2019\01\07\SO_54070456.cmd
copy "C:\TESTone\*.*" "C:\Jan-19"
move "C:\TESTone\*.*" "\\172.1.1.1\Shared-File\Jan-19\"

PowerShell 将返回带有当前文化的月份缩写MMM，以选择特殊的偏差文化使用：

(Get-Date).ToString('MMM-yy',(New-Object System.Globalization.CultureInfo("en-us")))

要查找文化，您可以使用 .dot Net 函数：

[globalization.cultureinfo]::GetCultures('allCultures')

Answer 3

根据您的区域设置，您可能需要稍微更改set destFolder=!month:~%d%,3!-%date:~8,2% 上的一些参数，这是因为我插入了一个回显以首先在屏幕上向您显示正在发生的事情。最后还有停顿。调试完成后，您可以取消暂停：

@echo off
setlocal EnableDelayedExpansion
for /F "tokens=1 delims=/" %%m in ("%date%") do (
   set /A "m=(1%%m%%100-1)*3"
)
set month=JanFebMarAprMayJunJulAugSepOctNovDec
set destFolder=!month:~%d%,3!-%date:~8,2%

set destFolder1=C:\%destFolder%\
echo copy "C:\TESTone\*.*" %destFolder1%
copy "C:\TESTone\*.*" %destFolder1%

set destFolder2=\\172.1.1.1\Shared-File\%destFolder%\
echo move "C:\TESTone\*.*" %destFolder2%
move "C:\TESTone\*.*" %destFolder2%

pause