【问题标题】:DAX Previous Month to date total is giving entire previous month's entire totalDAX 上个月迄今为止的总计是​​上个月的全部总计
【发布时间】:2016-12-07 19:32:23
【问题描述】:

我在 Power BI 中使用 DAX 计算迄今为止的上个月销售总额,以创建 KPI 视觉对象。即如果今天是 12 月 7 日,那么我想获得 11 月 1 日至 11 月 7 日的销售总额,并与当月至今进行比较。

CurrentMTD = TOTALMTD(SUM(SALES_VOUCHERS[SaleValue]),DatesTable[Date])

这很好用。 然而,上个月 YTD 给了我整个 11 月的总数。到目前为止,我已经尝试过以下方法

PMYTD = totalmtd(sum(SALES_VOUCHERS[SaleValue]),dateadd(DATESMTD(DatesTable[Date]),-1,month))

和

PMYTD = CALCULATE(sum(SALES_VOUCHERS[SaleValue]),
    DATESBETWEEN(DatesTable[Date],                    
        FIRSTDATE(PREVIOUSMONTH(DatesTable[Date])),   
        LASTDATE(DATEADD(DatesTable[Date],-1,MONTH))))

两者都返回相同的答案,即整个上个月的总数。 如果我只是在上述版本的日期之间硬编码开始和结束日期,那么我确实得到了想要的结果。但这不是解决方案。

我已将事实表 (Sales_VOUCHERS) 链接到 DatesTable,到目前为止,报告页面上没有其他视觉效果。 请协助我错过了什么以及如何获得上个月迄今为止的总计

【问题讨论】:

    标签: powerbi dax


    【解决方案1】:

    如果您在月份级别进行汇总(即,您查看的是 2016 年 12 月与 2016 年 11 月的对比),那么您上面的度量将显示整个 12 月与整个 11 月的比较(以及由于 12 月是偏月,而 11 月不是,因此会导致您看到的不匹配)。

    如果您过滤到当前日期(例如 12 月 7 日),那么您的 MTD 和上个月 MTD 度量将只显示对应月份的第 7 个。

    假设您不想过滤到日期级别(并非不合理),您可以增强您的公式以过滤掉未来的日期。例如:

     PMYTD = totalmtd(
        sum(SALES_VOUCHERS[SaleValue]),
        dateadd(
            FILTER(
                DATESMTD(DatesTable[Date]),
                DatesTable[Date]<TODAY()
            ),
            -1,
            month
        )
    )
    

    这表示,如果日期在今天之后,请不要将其传递到 TOTALMTD 计算中(因此它只会计算该月的前 7 天,例如,如果今天是 12 月 8 日 - 即使您是查看报告中的完整月份)。

    旁注:您还可以编写上个月的度量来重复使用您的 MTD 度量,而不是重新定义它。这样,如果您更改了 MTD 计算,之前的 MTD 计算会自动更新。

    PMYTD = CALCULATE(
        [CurrentMTD],
        DATEADD(
            FILTER(
                DatesTable[Date],
                DatesTable[Date]<TODAY()
            ),
            -1,
            MONTH
        )
    )
    

    有用的资源:

    1. https://www.powerpivotpro.com/2016/01/year-to-date-in-previousprior-year/(涵盖此问题和各种解决方案的文章)
    2. https://community.powerbi.com/t5/Desktop/Compare-MTD-with-previous-period/td-p/24656(同一问题的论坛讨论)
    3. http://community.powerbi.com/t5/Desktop/Time-Intelligence-TOTALMTD-vs-DATESMTD-vs-DATEADD/td-p/10088(关于 DATESMTD 与 TOTALMTD 的论坛讨论)

    【讨论】:

      猜你喜欢
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 2020-06-12
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多