如何将用户输入的字符串与批处理文件中的特殊字符进行比较？

Question

问题：如何比较用户输入的字符串包含特殊字符，例如 Windows Batch 中的7^7%7&7=7"7!7？

未完成的代码：

set/p str1=URL: 
rem if %str1%==7^7%7&7=7"7!7 (  // syntax error
rem if "%str1%"=="7^^7%%7^&7=7^"7!7" (  // still syntax error
    echo Nice
) else (
    echo Bad
)

预期输出：

> URL: 7^7%7&7=7"7!7
> Nice
> URL: 42
> Bad

附言用户输入的字符串在实际情况下实际上是有效的 url，因此所有valid url characters 都是可能的输入，对于与此问题类似的更一般情况，包括引号。

Answer 1

主要问题是不平衡的引号。条件：

if "%str1%"=="7^7%%7&7=7"7!7^" (
    echo Nice
) else (
    echo Bad
)

只要变量 str1 本身不包含（不平衡的）引号，就不应再自行返回语法错误（假设 delayed variable expansion 已禁用）。如您所见，%-symbol 必须加倍，独立于引号，但其他特殊字符只能在出现在引号之外时进行转义。最后一个引号被转义，因此无法识别。

但是如果你在提示符中输入7^7%7&7=7"7!7 仍然会失败，因为str1 中的引号，因为（立即）变量扩展发生在检测到特殊字符之前。防止条件失败的唯一方法，独立于用户输入，您必须使用延迟变量扩展：

set /P str1="URL: "
rem // At first, enable delayed variable expansion:
setlocal EnableDelayedExpansion
rem /* Then apply it by enclosing variables with `!!` rather than `%%`;
rem    there are now even more complex escape sequences necessary though: */
if "!str1!"=="7^^7%%7&7=7"7^^!7^" (
    echo Nice
) else (
    echo Bad
)
endlocal

您可能已经认识到，比较的正确表达式现在看起来很奇怪，因为延迟扩展可能需要一些额外的转义，具体取决于表达式是否包含感叹号。

为了避免需要这种相当混乱和难以辨认的转义表达式，请先将比较字符串分配给一个变量，同时延迟扩展仍然被禁用：

set /P str1="URL: "
rem /* Predefine comparison expression; you always have to double `%`-symbols,
rem    and you still need to escape some special characters that appear unquoted,
rem    but escaping sequences do not depend on whether or not there is a `!`: */
set "cmp1=7^7%%7&7=7"7!7^"
rem // At first, enable delayed variable expansion:
setlocal EnableDelayedExpansion
rem // Then apply it by enclosing variables with `!!` rather than `%%`:
if "!str1!"=="!cmp1!" (
    echo Nice
) else (
    echo Bad
)
endlocal