gnuplot：字符串值 xticlabel 和调整字体大小

Question

我想以直方图样式绘制数据，顶部带有“累积”曲线。我有以下问题：

我的数据由一列包含类别（“放电”）和一列包含属于相应类别的值的数量（“概率”）组成。类别列的最后一个值是“>100”，汇总了所有排放量大于最后一个数值（“100 m^3/s”）的发电厂。我还没有找到使用命令plot 'datafile.dat' using 1:2 with boxes ... 绘制最后一个类别和相应值的解决方案，因为（我假设）在这种情况下，只有 x-ticlabels 的数值被读出，所以最后一个类别丢失了。如果

我用这个命令plot 'datafile.dat' using 2:xtics(1) with boxes ... 绘制它，最后一个类别“>100”绘制得很好。

但是：如果我使用后一个命令，x 轴标签会以正常字体大小显示。即使我的代码中有set format x '\footnotesize \%10.0f' 行。

我已经阅读了plotcommand 行中的显式标签，这些标签覆盖了之前设置的格式样式，但无法使其适应我的代码。 Changing ytic font size in gnuplot epslatex (multiplot)

你知道怎么做吗？

Excel 截图可视化我想要实现的目标

'datafile.dat'
discharge probability cumulated
10 20 20% 
20 10 10%
30 5 5%
40 6 6%
50 4 4%
60 12 12%
70 8 8%
80 15 15%
90 20 20%
100 6 6%
>100 4 4%`

[terminal=epslatex,terminaloptions={size 15cm, 8cm font ",10"}]
set xrange [*:*]
set yrange [0:20]
set y2range [0:100]
set xlabel 'Discharge$' offset 0,-1
set ylabel 'No. of power plants' offset 10.5
set y2label 'Cumulated probability' offset -10
set format xy '$\%g$'
set format x '\footnotesize \%10.0f'
set format y '\footnotesize \%10.0f'
set format y2 '\footnotesize \%10.0f'
set xtics rotate by 45 center offset 0,-1
set style fill pattern border -1
set boxwidth 0.3 relative
set style line 1 lt 1 lc rgb 'black' lw 2 pt 6 ps 1 dt 2
plot 'datafile.dat' using 1:2 with boxes axes x1y1 fs pattern 6 lc black notitle, \
'datafile.dat' using 1:3 with linespoints axes x1y2 ls 1 notitle

Answer 1

我对你的数据文件感到困惑；第三列的数字似乎不是累积的，加起来也不是 100%。这是一个仅使用文件前两列的解决方案：

set term epslatex standalone header "\\usepackage[T1]{fontenc}"
set output 'test.tex'

stats "datafile.dat" using 2
total = STATS_sum

set xlabel "Discharge" offset 0, 1.5
set xtics rotate

set ylabel "No. of power plants"
set ytics nomirror
set yrange [0:*]

set y2label "Cumulative probability"
set y2tics
set y2range [0:]

set boxwidth 0.3 relative
set style line 1 lt 1 lc rgb 'black' lw 2 pt 6 ps 1 dt 2

plot \
'datafile.dat' using 2:xtic("\\footnotesize " . stringcolumn(1)) with boxes axes x1y1 fs pattern 6 lc black notitle, \
'datafile.dat' using ($2/total) smooth cumulative with linespoints axes x1y2 ls 1 notitle

set output

诀窍是在using 命令的每个标签前添加latex 命令\footnotesize。它还首先计算发电厂的总数以便计算概率，然后使用smooth cumulative 选项计算累积值。