Perl 6 $*ARGFILES.handles 在二进制模式下？

Question

我正在尝试 $*ARGFILES.handles，它似乎以二进制模式打开文件。

我正在编写一个 zip-merge 程序，它从每个文件中打印一行，直到没有更多行可供读取。

#! /usr/bin/env perl6

my @handles = $*ARGFILES.handles;

# say $_.encoding for @handles;

while @handles
{
  my $handle = @handles.shift;
  say $handle.get;
  @handles.push($handle) unless $handle.eof;
}

我这样调用它：zip-merge person-say3 repeat repeat2

它失败了：无法在 ./zip-merge 第 7 行的块中以二进制模式对句柄执行“获取”

指定的文件是文本文件（以 utf8 编码），我收到了关于不可执行文件和可执行文件（使用 perl6 代码）的错误消息。

注释掉的行说我给它的每个文件都是utf8，所以它们不应该是二进制的，

perl6 -v：这是基于 MoarVM 版本 2018.10 构建的 Rakudo 版本 2018.10

我做错了什么，还是发现了错误？

Answer 1

.handles 返回的 IO::Handle 对象已关闭。

my @*ARGS = 'test.p6';
my @handles = $*ARGFILES.handles;
for @handles { say $_ }
# IO::Handle<"test.p6".IO>(closed)

如果您只想让您的代码正常工作，请在分配给@handles 之后添加以下行。

.open for @handles;

原因是.handles 的迭代器是用IO::CatHandle.next-handle 编写的，它打开当前句柄并关闭前一个句柄。
问题是，在您有机会对它们进行任何工作之前，它们都有机会成为当前句柄和前一个句柄。
（也许.next-handle 和/或.handles 需要:!close 参数。）

---

假设您希望它像 roundrobin 那样工作，我实际上会写得更像这样：

# /usr/bin/env perl6
use v6.d;

my @handles = $*ARGFILES.handles;

# a sequence of line sequences
my $line-seqs = @handles.map(*.open.lines);
# Seq.new(
#   Seq.new( '# /usr/bin/env perl6', 'use v6.d' ), # first file
#   Seq.new( 'foo', 'bar', 'baz' ),                # second file
# )

for flat roundrobin $line-seqs {
  .say
}

# `roundrobin` without `flat` would give the following result

# ('# /usr/bin/env perl6', 'foo'),
# ('use v6.d', 'bar'),
# ('baz')

如果您为$line-seqs 使用了数组，则需要在将值传递给roundrobin 之前对它们进行去项目化(.<>)。

for flat roundrobin @line-seqs.map(*.<>) {
  .say
}

---

其实我个人更可能写出类似这种（长）单行字的东西。

$*ARGFILES.handles.eager».open».lines.&roundrobin.flat.map: *.put

Answer 2

:bin 是 always set in this type of objects。由于您正在处理句柄，因此您应该按照示例中的说明逐行阅读，或者重置句柄以使其不处于二进制模式。