抛光 gnuplot 直方图答案

【问题标题】：Polishing gnuplot histogram plot抛光 gnuplot 直方图
【发布时间】：2016-04-05 21:27:50
【问题描述】：

我正在尝试使用 1 到 12 个线程绘制某些数据集 1、2 和 3 的一些执行时间。根据其他合作者的提示，我设法绘制了一些东西，但仍然是原始的，需要进行一些修改。

test.dat 文件如下所示：

它是这样组织的：前 10 行是数据集 1 和 1 线程的执行时间；接下来的 10 次是数据集 2 和 1 线程的时间； 10 个下一个数据集 3、1 个线程，依此类推，最多 12 个线程。

gnuplot 脚本如下所示：

set boxwidth 0.7 relative
set style fill solid 1.0 noborder
set xtics ("1" 15, "2" 75, "3" 135, "4" 195, "5" 255, "6" 315, "7" 375, "8" 435, "9" 495, "10" 555, "11" 615, "12" 675)
unset key
set terminal png size 800,600 enhanced font "Helvetica,10"
set output 'output.png'
set xlabel "Number of threads"
set ylabel "Execution time"
plot for [i=1:12] 'test.dat' using ($0+(i-1)*60):1 every ::((i-1)*30)::(i*30-1) with boxes lt i

这个情节有几个问题：

数据集：我们可以看到，对于每个数据集，每个线程数都有 10 次执行。数据集 1 是最低值，ds 2 是中等值，ds 3 是最高值。每个线程数不应使用一种颜色，而应仅使用 3 种颜色，例如数据集 1 为红色，数据集 2 为绿色，数据集 3 为蓝色，这些颜色应通过右上角的设置键通知。
间距：绘图开始粘在左 y 轴上。例如，在第一个直方图和左侧 y 轴之前应该有 15 个单位的间距，在数据集之间应该有几个单位，在线程数之间也应该有 15 个单位，在最后一个直方图和右 y 轴之间应该有 15 个单位。
xtics：xtics 应考虑上述间距。是否可以循环这些 xtics 的设置？

提前致谢。

更新

Matthew，根据您对第 1 点的断言，以下是按数据集排序的执行时间（数据集 1：第 1 - 120 行；数据集 2：第 121 - 240 行；数据集 3：第 241 - 360 行）；给定 ds 的前 10 行代表 1 个线程的执行时间，接下来的 10 行代表 2 个线程，依此类推。

我还发布了该情节之前的样子，以便您衡量您在改进方面的帮助：

【问题讨论】：

我扩展了我的答案，为已排序的数据集提供了一个绘图命令，这样它就完整并涵盖了您提供的数据集的两种形式。请注意，对于已排序的数据集，every 的选择更简单，只有一个 for（因为我们不必处理交织），并且标题规范更简单。 x 坐标计算变得稍微复杂一些，但总的来说它是一个更简单的命令。

标签： gnuplot histogram

【解决方案1】：

我相信这会实现你想要的：

set xlabel "Number of threads"
set ylabel "Execution time"

set style fill solid 1.0 noborder

set boxwidth 0.7

set xtics ("1" 19.5)
set for[i=2:12] xtics add (sprintf("%d",i) (i-1)*55+19.5) 

set key top right

set xrange[-15:660]

plot for [i=0:2] for [j=0:9] 'test.dat' using ($0*55+j+i*15):1 every 30::(i*10+j) with boxes lt (i+1) t (j==0)?sprintf("Data Set %d",i+1):""

在这里，我们在两个边缘、线程之间插入 15 个单元，在数据集之间插入 5 个单元。我还将 boxwidth 设置为绝对而不是相对。

结果如下：

解决你的观点：

第 3 点

是的，可以使用set for 语法查看x-tics 的设置。在这里，我明确指定了第一个 xtic。这具有关闭除我指定的之外的所有 tic 的效果，然后我使用 set xtics add 命令添加额外的 xtics。如果我没有明确设置第一个，除了我的之外，我还会得到自动生成的抽动。

或者，我们可以在字符串中构建命令，然后执行它，使用

tcommand = "("
do for[i=1:12] {tcommand = sprintf("%s \"%d\" %f,",tcommand,i,(i-1)*55+19.5)}
tcommand = tcommand[1:strlen(tcommand)-1].")"
set xtics @tcommand

这里是tcommand的内容

( "1" 19.500000, "2" 74.500000, "3" 129.500000, "4" 184.500000, "5" 239.500000, "6" 294.500000, "7" 349.500000, "8" 404.500000, "9" 459.500000, "10" 514.500000, "11" 569.500000, "12" 624.500000)

但是，这仅在支持字符串宏时才有效。

请注意，线程部分的宽度是 3*10 + 2*5 + 15 = 55，因为三个数据集占用 10 个空格，它们之间有 2 个空格，5 个空格，1 个间隔 15 个空格。 19.5 将tic mark 直接放在中心数据集的中心。

第 2 点

这可以通过调整 xrange 轻松解决。如果我们将第一个框放在 0 处，我们可以在 -15 处开始 xrange 以离开左边的间隙。由于有 12 个线程单元，每个单元使用 55 个空格（包括间隙），我们可以将 xrange 的末端放置在 660。

第 1 点

这是比较棘手的部分，我怀疑可能有更好的方法。特别是，数据结构使这变得更加困难。如果列出数据集 1 的所有值，然后列出集合 2 的所有值，依此类推，会更容易。它们混合在一起的事实使它变得更加困难。

这里各种线程计数和数据点的行号如下所示：

               Data set 1
     1 thread   2 threads   3 threads ...
1st  0          30          60
2nd  1          31          61
...

               Data set 2
     1 thread   2 threads   3 threads ...
1st  10         40          70
2nd  11         41          71
...

every 命令不支持“每 30 个点开始 10 个连续行”，因此我们需要执行两个循环。第一个循环 (i) 将遍历数据集。第二个 (j) 将超过数据集中的行（第一行、第二行等）。

因此我们可以从 (i*10+j) 开始每 30 行读取一次。例如，当 i 和 j 都为 0 时，我们将读取第 0 行、第 30 行、第 60 行等等，即数据集 1 的每个线程集中的第一行。因此我们可以将这些值放在 $0*55 +j+i*15 其中$0的取值范围是0到11，因此可以用来选择线程组。

因为这意味着每个数据集将有 10 条曲线，所以我们只在第一条曲线上设置标题（将其设置为空会抑制它）。

在这里，我使用了默认的线型。要为每组设置特定的颜色，可以修改绘图命令，或者重新定义线型。

编辑：

对于OP提供的排序后的数据集，plot命令（其余命令保持不变）可以简化为

plot for [i=0:2] 'test.dat' u (i*15 + floor($0/10)*55 + int($0)%10):1 every ::(i*120)::((i+1)*120-1) w boxes t sprintf("Data set %d",i+1)

这里我们只需要遍历数据集。无需遍历行，因为我们可以在一个连续行块中读取每个数据集。对于每个数据集，every 符号选择与其对应的 120（行 0 - 119、120 - 239、240 - 359）。

为了计算 x 坐标，我们计算数据集的偏移量（第一个为 0，第二个为 15，第三个为 30），对应于前一组使用的 10 个单元块的数量加上间距为 5 个单位。为此，我们添加线程块的偏移量。为此，我们将行号（0 索引）除以 10（每个线程的测量次数）并将结果取底。因此，前十行给我们 0，接下来的 10 行给我们 1，依此类推。这告诉我们要跳过多少线程块，我们将其乘以线程块的大小 (55)。最后，我们在测量集中添加线的值。我们使用模运算来获取与线程块相关的实际行号，而不是数据集 (0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 0, 1, 2, ... )。因此i*15 + floor($0/10)*55 + int($0)%10 为我们提供了测量的 x 坐标。尽管 $0 只有整数值，但它被视为浮点数，因此我们强制转换为 int 以获取模数。

添加标签要简单得多，因为我们只需要循环每个数据集一次而不是 10 次，因此我们不必担心跳过后面的循环。

【讨论】：