通过 VBScript 关闭打开的进程（排除的除外）

Question

目前我使用 VBScript 的以下部分来关闭正在运行的进程，效果很好。但管理问题是，如果存在未知进程，脚本不会关闭它。因此，我想将其更改为终止所有正在运行的进程的位置，除非它们被明确排除（因为有一些进程我不想终止）。

Dim WshShell, objShell 
Set WshShell =  CreateObject("WScript.Shell")

AppList = "iexplore.exe,notepad.exe,wordpad.exe"

'Closing all open applications that are specified in AppList
For Each app In Split(appList, ",")
    Set objProcs=GetObject("winmgmts:\\.\root\cimv2").ExecQuery("select * from Win32_Process where Name= '" & app & "'")
    For Each process In objProcs
        On Error Resume Next
        process.Terminate
        On Error Goto 0
    Next
Next

我看过，但似乎找不到任何东西。而且我可以使用 PowerShell 命令（因为所有 PC 都是 Win10），只要 PS 命令可以完全在此 VBS 内运行，无需维护单独的 PS 文件。

所以这样的事情是可以接受的：

objShell.Run("powershell.exe -switch1 -switch2")

但不是这个：

objShell.Run("powershell.exe c:\scripts\test.ps1")

Answer 1

杀死除排除列表中的所有进程之外的所有进程的想法对我来说听起来很冒险。你真的能确定你的排除清单是完整的吗？可以随时添加新流程（您可能想要/需要）。这在专用机器上可能没问题，但我不会在我的通用 PC 上使用这种方法。无论如何，这是脚本。使用风险自负。

注意：将 KillEnabled 设置为 False，脚本仅显示将被杀死的 Exe 名称.将该值更改为 True 即可上线。使用 CScript 运行（例如 cscript killx.vbs）。

KillEnabled = False
UserExesOnly = True
Exclude = "applicationframehost,backgroundtaskhost,chsime,cmd,conhost,cscript,ctfmon,dllhost,explorer,mshta,runtimebroker,settingsynchost,searchapp,shellexperiencehost,sihost,smartscreen,startmenuexperiencehost,svchost,systemsettings,textinputhost,useroobebroker,video.ui,wscript"
Exclude = LCase(Exclude)
Set oWMI = GetObject("winmgmts:\\.\root\cimv2")
Set oWSH = WScript.CreateObject("WScript.Shell")
If UserExesOnly Then X = " Where SessionID = 1"
Set oProcesses = oWMI.ExecQuery("SELECT * FROM Win32_Process" & X)
For Each oProcess In oProcesses
  Kill = False
  ExeName = LCase(oProcess.Name)
  If InStr(ExeName,".exe") Then
    Kill = True
    For Each Exe In Split(Exclude,",")
      If InStr(ExeName,Exe & ".exe") Then Kill = False
    Next
    If Kill Then
      If KillEnabled Then
        oProcess.Terminate
      Else
        WScript.Echo ExeName
      End If
    End If
  End If
Next